XSLT - получить имя файла из URL - PullRequest
Новая
       10

XSLT - получить имя файла из URL

4 голосов
/ 09 августа 2011

Мне нужно получить имя файла из URL-адреса, URL-адрес является динамическим, а количество слешей может быть разным.Я использую xslt 1.0, поэтому ищу что-то, что займет:

http://DevSite/sites/name/Lists/note/Attachments/3/image.jpg

и даст мне:

image.jpg

Это возможно вXSLT 1.0?

Ответы [ 2 ]

6 голосов
/ 17 апреля 2013

если вы используете xslt 2.0, вы можете использовать subsequence () и создать функцию:

Объявите вашу функцию в корне таблицы стилей xsl: 

xmlns:myNameSpace="http://www.myNameSpace.com/myfunctions"

Создать функцию: 

<xsl:function name="myNameSpace:getFilename">
    <xsl:param name="str"/>
    <!--str e.g. document-uri(.), filename and path-->
    <xsl:param name="char"/>
    <xsl:value-of select="subsequence(reverse(tokenize($str, $char)), 1, 1)"/>
</xsl:function>

Вызовите функцию: 

<xsl:value-of select="myNameSpace:getFilename('http://DevSite/sites/name/Lists/note/Attachments/3/image.jpg', '/')"/>
5 голосов
/ 09 августа 2011

Вы можете использовать рекурсию: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">
        <xsl:variable name="url">http://DevSite/sites/name/Lists/note/Attachments/3/image.jpg</xsl:variable>

        <xsl:call-template name="get-file-name">
            <xsl:with-param name="input" select="$url"/>
        </xsl:call-template>

    </xsl:template>

    <xsl:template name="get-file-name">
        <xsl:param name="input"/>

        <xsl:choose>
            <xsl:when test="contains($input, '/')">
                <xsl:call-template name="get-file-name">
                    <xsl:with-param name="input" select="substring-after($input, '/')"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$input"/>
            </xsl:otherwise>
        </xsl:choose>

    </xsl:template>

</xsl:stylesheet>

Выход: image.jpg

...