Эхо все псевдонимы в зш - PullRequest
Новая
       17

Эхо все псевдонимы в зш

2 голосов
/ 15 февраля 2012

Можно ли заставить zsh отображать фактические команды, на которые ссылаются все псевдонимы, когда они используются?

Например, скажем, что у меня установлены следующие псевдонимы: 

# List direcory contents
alias lsa='ls -lah'
alias l='ls -la'
alias ll='ls -l'

Когда я выполняю их, я бы хотел, чтобы каждый из них печатал действительную команду, которая была выполнена.Например, я хотел бы видеть следующее: 

$ ll
executing: 'ls -l'
total 0
-rw-r--r--  1 person  staff  0 Feb 15 13:46 cool.txt
-rw-r--r--  1 person  staff  0 Feb 15 13:46 sweet.html
-rw-r--r--  1 person  staff  0 Feb 15 13:46 test.md

Вместо следующего: 

$ ll
total 0
-rw-r--r--  1 person  staff  0 Feb 15 13:46 cool.txt
-rw-r--r--  1 person  staff  0 Feb 15 13:46 sweet.html
-rw-r--r--  1 person  staff  0 Feb 15 13:46 test.md

Есть ли одна команда, которую я могу добавить в свой zshrc, чтобы это произошлодля всех псевдонимов?Я бы предпочел не изменять каждый псевдоним.

1 Ответ

6 голосов
/ 16 февраля 2012

Если у вас все в порядке с отображением псевдонимов, если псевдоним является первым словом, присутствующим в командной строке, вы можете попытаться вставить следующий код в ваш .zshrc: 

_-accept-line () {
    emulate -L zsh
    local -a WORDS
    WORDS=( ${(z)BUFFER} )
    # Unfortunately ${${(z)BUFFER}[1]} works only for at least two words,
    # thus I had to use additional variable WORDS here.
    local -r FIRSTWORD=${WORDS[1]}
    local -r GREEN=$'\e[32m' RESET_COLORS=$'\e[0m'
    [[ "$(whence -w $FIRSTWORD 2>/dev/null)" == "${FIRSTWORD}: alias" ]] &&
        echo -nE $'\n'"${GREEN}Executing $(whence $FIRSTWORD)${RESET_COLORS}"
    zle .accept-line
}
zle -N accept-line _-accept-line

Описание (пропущены некоторые тривиальные вещи): 

emulate -L zsh # Reset some options to zsh defaults (locally).
               # Makes function immune to user setup.

local -a WORDS # Declare WORDS as an array local to function

${(z)VARNAME}  # Split VARNAME using command-line parser.
               # Things like “"first word" "second word"” get split into 2 words:
               # “"first word"” “"second word"”

$BUFFER        # Variable containing the whole command-line. Can be modified

local -r V     # Declare variable “V” as read-only

$'\e[32m'      # Escape code for green foreground color in most terminals
$'\e[0m'       # Sequence that being echoed to terminal clears out color information

whence -w cmd  # Display type of the command in format “cmd: type”
whence cmd     # If “cmd” is an alias, then this command outputs alias value

zle .accept-line # Call internal zle “accept-line” widget. This must be done or 
               # every command will turn to no-op. You can, of course, replace
               # this with “eval $BUFFER” but I can’t say what will break in this case

zle -N accept-line _-accept-line # Associate widget “accept-line” with function
               # “_-accept-line”. This makes this function responsible for accepting
               # lines.

Дополнительная информация в man zshbuiltins (emulate, whence, local), man zshzle (zle, $BUFFER), man zshparam (${(z)}).

...