XSL media: content - Обрезка строк в XSLT

Question

Может кто-нибудь сказать мне, как выбрать URL из этого:

<media:content url="http://feedproxy.google.com/~r/TEDTalks_video/~5/aZWq6PY05YE/TimBrown_2009G.mp4" fileSize="57985745" type="video/mp4" />

Я хочу:

1. Создать ссылку на этот файл:

2. Обрезать URL с:

   http://feedproxy.google.com/~r/TEDTalks_video/~5/aZWq6PY05YE/TimBrown_2009G.mp4

до:

TimBrown_2009G

и затем возьмите TimBrown_2009G и используйте его как часть URL

Answer 1

Выбор URL. Вам просто нужно убедиться, что у вас правильный URI пространства имен.

<xsl:value-of xmlns:media="http://search.yahoo.com/mrss/" 
              select="media:content/@url"/>

Обрезка URL. Как это сделать лучше всего, зависит от того, используете ли вы XSLT 1 или 2, так как последний имеет лучшие функции обработки строк из XPath 2.0.

Если вы используете XSLT 1, вы можете создать вспомогательный шаблон для возврата последнего сегмента из строки с разделителями:

<xsl:template name="last-substring-after">
  <xsl:param name="string"/>
  <xsl:param name="separator"/>
  <xsl:choose>
    <xsl:when test="contains($string, $separator)">
      <xsl:call-template name="last-substring-after">
        <xsl:with-param name="string"
                        select="substring-after($string, $separator)"/>
        <xsl:with-param name="separator"
                        select="$separator"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$string"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Затем вы можете использовать это для извлечения последнего сегмента URL-адреса и продолжения извлечения части перед точкой. Предполагая, что URL находится в переменной url:

<xsl:variable name="name">
  <xsl:call-template name="last-substring-after">
    <xsl:with-param name="string" select="$url"/>
    <xsl:with-param name="separator" select="'/'"/>
  </xsl:call-template>
</xsl:variable>
<xsl:value-of select="substring-before($name, '.')"/>