Получение пароля Windows EC2 от экземпляров при использовании Terraform - PullRequest
Новая
       379

Получение пароля Windows EC2 от экземпляров при использовании Terraform

1 голос
/ 18 мая 2019

Я пытаюсь получить пароль от пары новых экземпляров ec2 при использовании terraform. Прочитал пару постов и подумал, что он у меня есть, но никуда не денется.

Вот мой конфиг: 

resource "aws_instance" "example" {
  ami = "ami-06f9d25508c9681c3"
  count         = "2"
  instance_type = "t2.small"
  key_name = "mykey"
  vpc_security_group_ids =["sg-98d190fc","sg-0399f246d12812edb"]
  get_password_data = "true"
}

output "public_ip" {
    value = "${aws_instance.example.*.public_ip}"
}

output "public_dns" {
    value = "${aws_instance.example.*.public_dns}"
}

output "Administrator_Password" {
    value = "${rsadecrypt(aws_instance.example.*.password_data, 
file("mykey.pem"))}"
}

Удалось очистить все синтаксические ошибки, но теперь при запуске выдается следующая ошибка: 

PS C:\tf> terraform apply
aws_instance.example[0]: Refreshing state... (ID: i-0e087e3610a8ff56d)
aws_instance.example[1]: Refreshing state... (ID: i-09557bc1e0cb09c67)

Error: Error refreshing state: 1 error(s) occurred:

* output.Administrator_Password: At column 3, line 1: rsadecrypt: argument 1 
should be type string, got type list in:

${rsadecrypt(aws_instance.example.*.password_data, file("mykey.pem"))}

1 Ответ

1 голос
/ 20 мая 2019

Эта ошибка возвращается, поскольку aws_instance.example.*.password_data - это список password_data результатов для каждого из экземпляров EC2.Каждый из них должен быть расшифрован отдельно с помощью rsadecrypt.

. Для этого в Terraform v0.11 необходимо использовать null_resource в качестве обходного пути для достижения операции «для каждой»: 

resource "aws_instance" "example" {
  count = 2

  ami                    = "ami-06f9d25508c9681c3"
  instance_type          = "t2.small"
  key_name               = "mykey"
  vpc_security_group_ids = ["sg-98d190fc","sg-0399f246d12812edb"]
  get_password_data      = true
}

resource "null_resource" "example" {
  count = 2

  triggers = {
    password = "${rsadecrypt(aws_instance.example.*.password_data[count.index], file("mykey.pem"))}"
  }
}

output "Administrator_Password" {
    value = "${null_resource.example.*.triggers.password}"
}

Начиная с Terraform v0.12.0, это можно упростить с помощью новой for конструкции выражения: 

resource "aws_instance" "example" {
  count = 2

  ami                    = "ami-06f9d25508c9681c3"
  instance_type          = "t2.small"
  key_name               = "mykey"
  vpc_security_group_ids = ["sg-98d190fc","sg-0399f246d12812edb"]
  get_password_data      = true
}

output "Administrator_Password" {
  value = [
    for i in aws_instance.example : rsadecrypt(i.password_data, file("mykey.pem"))
  ]
}
...