Как установить порядок включения для cmake

Question

Я использую cmake для генерации Makefile для проекта. В верхнем CMakeLists.txt мне нужно включить некоторые подмодули. Так это как:

include(cmake/Modules/pcre-8.40.cmake)
include(cmake/Modules/curl-7.64.1.cmake)
include(cmake/Modules/openssl-1.1.1.cmake)

Curl-7.64.1.cmake похож на:

include(ExternalProject)

set (PCAP_ROOT        ${CMAKE_BINARY_DIR}/third_party/curl)
set (PCAP_LIB_DIR     ${PCAP_ROOT}/lib)
set (PCAP_INCLUDE_DIR ${PCAP_ROOT}/include)
set (OPENSSL_DIR      ${CMAKE_BINARY_DIR}/third_party/openssl/build)
set (OPENSSL_I_DIR  ${OPENSSL_DIR}/include)
set (OPENSSL_L_DIR    ${OPENSSL_DIR}/lib)

set (PCAP_CONFIGURE    cd ${PCAP_ROOT}/src/curl-7.64.1 && cmake -DOPENSSL_ROOT_DIR=${OPENSSL_DIR} -DOPENSSL_INCLUDE_DIR=${OPENSSL_I_DIR} -DOPENSSL_SSL_LIBRARY=${OPENSSL_L_DIR}/libssl.a -DOPENSSL_CRYPTO_LIBRARY=${OPENSSL_L_DIR}/libcrypto.a -DBUILD_SHARED_LIBS=OFF -DBUILD_TESTING=OFF -DCMAKE_INSTALL_PREFIX=${PCAP_ROOT} -DBUILD_CURL_EXE=OFF . -DCMAKE_TOOLCHAIN_FILE=${CMAKE_TOOLCHAIN_FILE})
set (PCAP_MAKE         cd ${PCAP_ROOT}/src/curl-7.64.1 && make)
set (PCAP_INSTALL      cd ${PCAP_ROOT}/src/curl-7.64.1 && make install)

ExternalProject_Add(curl-7.64.1
        URL         ${CMAKE_SOURCE_DIR}/third_party/curl/curl-7.64.1.zip
        DOWNLOAD_NAME       curl-7.64.1
        PREFIX          ${PCAP_ROOT}
        CONFIGURE_COMMAND   ${PCAP_CONFIGURE}
        BUILD_COMMAND       ${PCAP_MAKE}
        INSTALL_COMMAND     ${PCAP_INSTALL}
        )

include_directories (${CMAKE_BINARY_DIR}/third_party/curl/include)
link_directories (${CMAKE_BINARY_DIR}/third_party/curl/lib)

OpenSSL-1.1.1.cmake:

include(ExternalProject)

set (OPENSSL_ROOT        ${CMAKE_BINARY_DIR}/third_party/openssl)
set (OPENSSL_LIB_DIR     ${OPENSSL_ROOT}/lib)
set (OPENSSL_INCLUDE_DIR ${OPENSSL_ROOT}/include)
set (OPENSSL_INSTALL_DIR ${CMAKE_BINARY_DIR}/third_party/openssl/build)
set (OPENSSL_ROOT_DIR    ${CMAKE_BINARY_DIR}/third_party/openssl)

if (DEFINED CROSS)
    set (OPENSSL_CONFIGURE    cd ${OPENSSL_ROOT}/src/openssl && 
    ./Configure linux-aarch64 no-shared no-asm --prefix=${OPENSSL_INSTALL_DIR} 
    --cross-compile-prefix=${CROSS}- --sysroot=${CMAKE_SYSROOT})  
    set (OPENSSL_MAKE         cd ${OPENSSL_ROOT}/src/openssl && make CC=${CROSS}-gcc AR=${CROSS}-ar  RANLIB=${CROSS}-ranlib)
else()
    set (OPENSSL_CONFIGURE    cd ${OPENSSL_ROOT}/src/openssl && ./config no-shared no-asm --prefix=${OPENSSL_INSTALL_DIR})
    set (OPENSSL_MAKE         cd ${OPENSSL_ROOT}/src/openssl && make)
endif()
set (OPENSSL_INSTALL      cd ${OPENSSL_ROOT}/src/openssl && make install)

ExternalProject_Add(openssl
        URL         ${CMAKE_SOURCE_DIR}/third_party/openssl/openssl-OpenSSL_1_1_1-stable.zip
        DOWNLOAD_NAME       openssl
        PREFIX          ${OPENSSL_ROOT}
        CONFIGURE_COMMAND   ${OPENSSL_CONFIGURE}
        BUILD_COMMAND       ${OPENSSL_MAKE}
        INSTALL_COMMAND     ${OPENSSL_INSTALL}
        )

include_directories (${CMAKE_BINARY_DIR}/third_party/openssl/build/include)
link_directories (${CMAKE_BINARY_DIR}/third_party/openssl/build/lib)

Как видите, для curl требуется openssl, но я не могу контролировать порядок. Таким образом, на разных компьютерах могут возникать ошибки, потому что openssl компилируется после curl. Так как я могу убедиться, что openssl скомпилирован первым?

Answer 1

Первый параметр ExternalProject_Add - это имя target , которое будет создано для внешнего проекта. Командой add_dependencies можно ограничить порядок, в котором будут создаваться внешние проекты:

# Curl is built *after* the openssl have been built.
add_dependencies(curl-7.64.1 openssl)