Функция текстуры в фрагментном шейдере дает ошибку

Question

Это мой фрагментный шейдер, и когда я пытаюсь использовать Cubemap в функции текстуры, я получаю сообщение об ошибке:

0,54 Не найдена соответствующая функция (используется неявное преобразование)

0,54 функция текстуры неизвестна.

Функция текстуры работает с texture2D.

#version 330 core
out vec4 FragColor;

 struct Light {
  vec3 direction;     
  vec3 ambient;
  vec3 diffuse;
  vec3 specular;
};

struct Material {
  vec3 ambient;
  vec3 diffuse;
  vec3 specular;
  float shininess;
  float opacity; 
}; uniform Material material;

uniform vec3 viewPos;
uniform Light light;
in vec3 FragPos;  
in vec3 Normal; 
in vec2 TexCoord; 
uniform bool UseColorMap;
uniform sampler2D texture1;
uniform samplerCube texturecubeMap;

void main()
 {  
    vec3 ambient = 0.2 * (light.ambient * material.ambient );

 // diffuse
 vec3 norm = normalize( Normal );
 vec3 lightDir = normalize( -light.direction );
 float diff = max( dot( norm, lightDir) , 0.0 );
 vec3 diffuse = light.diffuse * diff * material.diffuse;

 // specular
  vec3 viewDir = normalize( viewPos - FragPos );
  vec3 reflectDir = reflect( -lightDir , norm );
  float spec = pow(max(dot(viewDir, reflectDir), 0.0), 
  material.shininess);
  vec3 specular = light.specular * spec * material.specular;
  vec3 result = ambient + diffuse + specular;
  vec3 texDiffuseColor =  texture( texture1 , TexCoord ).rgb;

if( !UseColorMap )
 {
    FragColor =  vec4( result ,  material.opacity / 100.0 );
 }
else
 {
 //FragColor =  texture( texture1 , TexCoord )  * vec4( result , 
  material.opacity / 100.0 );  // This works fine
  FragColor =   texture(  texturecubeMap , TexCoord ); // Get error here

 }
};

Answer 1

В случае сэмплера samplerCube координата текстуры должна быть 3-мерной, поскольку координата текстуры обрабатывается как вектор направления (rx ry rz), исходящий из центра куба.
Вызывается ошибка компиляциипотому что TexCoord является двухмерным.

К счастью, вы рассчитали направление обзора в мировом пространстве:

vec3 viewDir = normalize(viewPos - FragPos);

viewDir - правильный вектор направлениядля карты окружающей среды:

FragColor = texture(texturecubeMap, viewDir);