Построить серию datetimes с исключениями в эликсире - PullRequest
Новая
       56

Построить серию datetimes с исключениями в эликсире

0 голосов
/ 15 июня 2019

Я хотел бы создать список доступных временных интервалов между двумя датами, удаляя забронированные временные интервалы.

Во-первых, есть список time_slots, которые являются кортежами {start_time, end_time} и доступны для бронирования в любой день: 

time_slots = [
  {~T[09:00:00], ~T[13:00:00]},
  {~T[13:00:00], ~T[17:00:00]},
  {~T[17:00:00], ~T[21:00:00]}
]

Затем есть список bookings, который содержит кортежи {booking_start, booking_end}: 

bookings = [
  {~N[2019-06-14 09:00:00Z], ~N[2019-06-14 17:00:00Z]},
  {~N[2019-06-15 09:00:00Z], ~N[2019-06-15 13:00:00Z]},
  # some bookings may sit outside a slot range
  {~N[2019-06-16 15:00:00Z], ~N[2019-06-16 21:00:00Z]}
]

Также существует кортеж, содержащий {start_date, end_date}, который мы хотели бы сгенерировать всеми доступными временными интервалами между. 

start_end = {~N[2019-06-13 01:00:00Z], ~N[2019-06-16 23:00:00Z]}

В этом случае мы бы хотели сгенерировать все доступные временные интервалы и вернуть: 

available_slots = [
  {~N[2019-06-13 09:00:00Z], ~N[2019-06-13 13:00:00Z]},
  {~N[2019-06-13 13:00:00Z], ~N[2019-06-13 17:00:00Z]},
  {~N[2019-06-13 17:00:00Z], ~N[2019-06-13 21:00:00Z]},
  {~N[2019-06-14 17:00:00Z], ~N[2019-06-14 21:00:00Z]},
  {~N[2019-06-15 13:00:00Z], ~N[2019-06-15 17:00:00Z]},
  {~N[2019-06-15 17:00:00Z], ~N[2019-06-15 21:00:00Z]},
  {~N[2019-06-16 09:00:00Z], ~N[2019-06-16 13:00:00Z]}
]
  • Для того, чтобы занять временной интервал, потребуется либо начало, либо окончание бронирования, чтобы перекрыться внутрииз него (независимо от того, насколько мало это перекрытие):
    • например, при бронировании 0900–1000 будут заполнены временные интервалы 0900–1300, 0900–1700 и 0900–2100
  • Временной интервал может быть заполнен более чем одним бронированием:
    • например, у нас могут быть заказы 0900–1000 и 1000–1200, которые оба поместятся внутри0900–1300 временных интервалов.

1 Ответ

1 голос
/ 15 июня 2019

Вот возможное решение, вставьте код в файл timeslots.exs и запустите elixir timeslots.exs.

Предприняты следующие шаги:

  1. Создайте список всех доступных временных интервалов, которые вписываются в start_end
  2. Удалите перекрывающиеся слоты при бронировании

Проверка has_overlap? была немного хитрой, может потребоваться дополнительное тестирование. Он также удаляет слот затмевший , когда параметр booking_start находится до, а параметр booking_end находится после слота. 

defmodule TimeSlots do
  def available_time_slots(bookings, time_slots, start_end) do
    time_slots_in_range(time_slots, start_end)
    |> remove_booked_slots(bookings)
  end

  # Build a list with all time_slots between start_date_time and end_date_time
  defp time_slots_in_range(time_slots, {start_date_time, end_date_time}) do
    start_date = NaiveDateTime.to_date(start_date_time)
    end_date = NaiveDateTime.to_date(end_date_time)

    Date.range(start_date, end_date)
    |> Enum.map(fn date -> daily_time_slots(date, time_slots) end)
    |> List.flatten
    |> Enum.filter(fn {slot_start_date_time, slot_end_date_time} ->
      NaiveDateTime.compare(start_date_time, slot_start_date_time) != :gt &&
      NaiveDateTime.compare(end_date_time, slot_end_date_time) != :lt
    end)
  end

  defp daily_time_slots(date, time_slots) do
    Enum.map(time_slots, &(create_time_slot(date, &1)))
  end

  defp create_time_slot(date, {start_time, end_time}) do
    {:ok, start_date_time} = NaiveDateTime.new(date, start_time)
    {:ok, end_date_time} = NaiveDateTime.new(date, end_time)
    {start_date_time, end_date_time}
  end

  defp remove_booked_slots(time_slots, bookings) do
    Enum.reject(time_slots, fn time_slot ->
      Enum.reduce(bookings, false, fn booking, acc ->
        acc or has_overlap?(booking, time_slot)
      end)
    end)
  end

  # (slot_start <= booking_start < slot_end)
  # or (slot_start < booking_end <= slot_end)
  # or (booking_start <= slot_start and slot_end <= booking_end)
  defp has_overlap?({booking_start, booking_end}, {slot_start, slot_end}) do
    (NaiveDateTime.compare(slot_start, booking_start) != :gt &&
     NaiveDateTime.compare(booking_start, slot_end) == :lt) ||
    (NaiveDateTime.compare(slot_start, booking_end) == :lt &&
     NaiveDateTime.compare(booking_end, slot_end) != :gt) ||
    (NaiveDateTime.compare(booking_start, slot_start) != :gt &&
     NaiveDateTime.compare(slot_end, booking_end) != :gt)
  end
end


time_slots = [
  {~T[09:00:00], ~T[13:00:00]},
  {~T[13:00:00], ~T[17:00:00]},
  {~T[17:00:00], ~T[21:00:00]}
]

bookings = [
  {~N[2019-06-14 09:00:00Z], ~N[2019-06-14 17:00:00Z]},
  {~N[2019-06-15 09:00:00Z], ~N[2019-06-15 13:00:00Z]},
  # some bookings may sit outside a slot range
  {~N[2019-06-16 15:00:00Z], ~N[2019-06-16 21:00:00Z]}
]

# I've changed the end date to 2019-06-16 to match the expected result
start_end = {~N[2019-06-13 01:00:00Z], ~N[2019-06-16 23:00:00Z]}

available_slots = [
  {~N[2019-06-13 09:00:00Z], ~N[2019-06-13 13:00:00Z]},
  {~N[2019-06-13 13:00:00Z], ~N[2019-06-13 17:00:00Z]},
  {~N[2019-06-13 17:00:00Z], ~N[2019-06-13 21:00:00Z]},
  {~N[2019-06-14 17:00:00Z], ~N[2019-06-14 21:00:00Z]},
  {~N[2019-06-15 13:00:00Z], ~N[2019-06-15 17:00:00Z]},
  {~N[2019-06-15 17:00:00Z], ~N[2019-06-15 21:00:00Z]},
  {~N[2019-06-16 09:00:00Z], ~N[2019-06-16 13:00:00Z]}
]

# Test it
IO.inspect TimeSlots.available_time_slots(bookings, time_slots, start_end)

Должен дать правильный результат: 

[
  {~N[2019-06-13 09:00:00], ~N[2019-06-13 13:00:00]},
  {~N[2019-06-13 13:00:00], ~N[2019-06-13 17:00:00]},
  {~N[2019-06-13 17:00:00], ~N[2019-06-13 21:00:00]},
  {~N[2019-06-14 17:00:00], ~N[2019-06-14 21:00:00]},
  {~N[2019-06-15 13:00:00], ~N[2019-06-15 17:00:00]},
  {~N[2019-06-15 17:00:00], ~N[2019-06-15 21:00:00]},
  {~N[2019-06-16 09:00:00], ~N[2019-06-16 13:00:00]}
]
...