Объединить результаты запросов в Google Sheets с несоответствующими размерами результатов

Question

Я пытаюсь создать единую формулу, в которую я могу добавлять запросы, чтобы иметь разные критерии и алгоритмы сортировки.Результаты будут иметь разные размеры, но все будут исходить из одного листа.Вот что я пытался:

=ARRAYFORMULA(IFERROR({iferror(QUERY(Available!$A$3:$M, "select A,B,C,D,E,F,G,H,I,J,K,L,M where M like '%Blah' order by B desc");iferror(QUERY(Available!$A$3:$M, "select A,B,C,D,E,F,G,H,I,J,K,L,M where C = 'Bleh' order by B asc limit 3"),A2:M2/0)})))

В приведенном выше примере первый запрос просматривает лист и находит набор столбцов, где столбец M содержит «Blah», упорядочивает его и предоставляет результаты.Это отлично работает.Когда я добавляю второй запрос, я хочу добавить результаты к предыдущему запросу.Я хочу иметь возможность продолжать строить эту формулу, чтобы в будущем я мог добавить больше запросов, которые будут отсортированы и ограничены независимо.Во втором запросе я хочу получить только 3 результата, которые упорядочены в обратном порядке и имеют столбец C с надписью «Bleh».

Answer 1

это может быть просто как:

=IFERROR(QUERY(
 {IFERROR(QUERY(Available!A3:M, "where M like '%Blah' order by B desc", 0), 
 {"","","","","","","","","","","","",""});
 IFERROR(QUERY(Available!A3:M, "where C = 'Bleh' order by B desc", 0), 
 {"","","","","","","","","","","","",""})}, 
 "where Col1 is not null", 0))

Answer 2

Разобрался. Это была проблема синтаксиса с использованием более простого примера. Я смог заставить его работать, используя это:

={QUERY(Available!$A$3:$M, "select A,B,C,D,E,F,G,H,I,J,K,L,M where M like '%Blah' order by B desc");QUERY(Available!$A$3:$M, "select A,B,C,D,E,F,G,H,I,J,K,L,M where C = 'Bleh' order by B desc")}

Первоначально я пробовал это, но использовал , в качестве разделителя, который используется для объединения диапазонов с использованием столбцов. Чтобы использовать строки для объединения диапазонов, необходимо использовать ; в качестве разделителя.