Ардуино не ложится спать при прерывании бега - PullRequest
Новая
       14

Ардуино не ложится спать при прерывании бега

1 голос
/ 16 июня 2019

Я написал небольшой скрипт для измерения скорости ветра с помощью анемометра.Я хочу измерить на 2 секунды, чем спать в течение 8 секунд ...

Если нет ветра, сон работает нормально, но пока вращается анемометр, Arduino не ложится спать.Как бы я исправить свой код, чтобы заснуть, несмотря ни на что.

Вот мой код .. 

#include "LowPower.h"

const byte interruptPin = 3;  // anemomter input to digital pin
volatile unsigned long elapsedTime = 0;
int interval;
long WindAvr = 0;       // sum of all wind speed between update
int measure_count = 0;  // count each mesurement
unsigned int WindSpeed;

void setup() {
    Serial.begin(9600);
    attachInterrupt(
        digitalPinToInterrupt(interruptPin), anemometerISR,
        FALLING);  // setup interrupt on anemometer input pin, interrupt will
                   // occur whenever falling edge is detected
}

void loop() {
    WindAvr = 0;
    measure_count = 0;
    sei();        // Enables interrupts
    delay(2000);  // Wait x second to average
    cli();        // Disable interrupts
    LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);

    WindSpeed = WindAvr / measure_count;
    Serial.println(WindSpeed);
}
void anemometerISR() {
    cli();  // Disable interrupts
    static unsigned long previousTime = 0;
    unsigned long time = millis();

    if (time - previousTime > 15) {  // debounce the switch contact.
        elapsedTime = time - previousTime;
        previousTime = time;

        if (elapsedTime < 2000) {
            interval = (22500 / elapsedTime) * 0.868976242;
            WindAvr += interval;  // add to sum of average wind values
            ++measure_count;      // add +1 to counter

        } else {
            ++measure_count;  // add +1 to counter
        }
    }

    sei();  // Enables interrupts
}

1 Ответ

2 голосов
/ 16 июня 2019

Внешнее прерывание - когда-то «немаскированное» - имеет возможность разбудить устройство, даже если глобальный флаг I не установлен с помощью cli().

Изменение 

cli();        // Disable interrupts
LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);

до 

detachInterrupt(digitalPinToInterrupt(interruptPin));
LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
attachInterrupt(digitalPinToInterrupt(interruptPin), anemometerISR, FALLING);

Также ... Я считаю, что ваши заявления cli() и sei() в ISR не нужны.Бит разрешения глобального прерывания автоматически отключается / включается при входе / выходе из ISR.Из руководства Atmega644:

При возникновении прерывания бит I разрешения глобального прерывания очищается, и все прерывания отключаются.Программное обеспечение пользователя может записывать логическую единицу в I-бит для включения вложенных прерываний.Все разрешенные прерывания могут прервать текущую процедуру прерывания.Бит I устанавливается автоматически при выполнении команды возврата из прерывания - RETI.

...