Как я могу получить сумму предметов в мультислоте - PullRequest
Новая
       10

Как я могу получить сумму предметов в мультислоте

0 голосов
/ 18 марта 2019

У меня есть шаблон, подобный показанному ниже.Как я могу получить сумму предметов в многослотовых оценках? 

(deftemplate student
  (multislot name)
  (multislot grades)
)

Ответы [ 2 ]

2 голосов
/ 18 марта 2019

Вот один из способов сделать это. В правиле reg6 функции + задаются два аргумента, равные 0, в дополнение к оценкам, чтобы гарантировать, что разрешенная функция + имеет как минимум 2 аргумента; в противном случае, если для учащегося будет ноль или один класс, вы получите ошибку. 

         CLIPS (6.31 2/3/18)
CLIPS> 
(deftemplate student
  (multislot name)
  (multislot grades))
CLIPS> 
(deftemplate sum
   (multislot name)
   (slot grade))
CLIPS>    
(defrule reg6
   (student (name $?name)
            (grades $?grades))
   =>
   (assert (sum (name ?name)
                (grade (+ 0 0 (expand$ ?grades))))))
CLIPS> 
(assert (student (name David Green) (grades))
        (student (name Sue Brown) (grades 90))
        (student (name Frank Black) (grades 85 75)))
<Fact-3>
CLIPS> (run)
CLIPS> (facts)
f-0     (initial-fact)
f-1     (student (name David Green) (grades))
f-2     (student (name Sue Brown) (grades 90))
f-3     (student (name Frank Black) (grades 85 75))
f-4     (sum (name Frank Black) (grade 160))
f-5     (sum (name Sue Brown) (grade 90))
f-6     (sum (name David Green) (grade 0))
For a total of 7 facts.
CLIPS>
1 голос
/ 18 марта 2019

Вы можете использовать функцию expand$.Обратитесь к Основному руководству по программированию в главе Multifield Expansion Function, чтобы узнать больше. 

(deftemplate student 
  (multislot name) 
  (multislot grades))  

(defrule grades-sum 
  (student (grades $?grades)) 
  => 
  (printout t "Student grades sum is " (+ (expand$ ?grades)))) 

(assert (student (grades (create$ 1 2 3 4 5)))) 
(student (name) (grades 1 2 3 4 5))

(run)       
Student grades sum is 15
...