Как решить код повернутой гистограммы? - PullRequest
Новая
       16

Как решить код повернутой гистограммы?

1 голос
/ 07 мая 2019

Привет всей группе stackoverflow,

У меня возник ряд проблем при определении диапазона осей в моем графике и формате в целом, и я хотел бы поделиться им с вами, чтобы увидеть, если среди всех насмогу найти ошибку

Я нашел на этом сайте пользователя, который сделал его похожим.Моя идея состоит в том, чтобы иметь что-то похожее, как на графике ссылки ниже.Но по какой-то причине, это, вероятно, глупо, это не выглядит правильно.

Мой код выглядит следующим образом: 


set term post eps enhanced color "Times-Roman" 14
set output "ComparacionPurezaMetodos.eps"

set key off 
set style data histogram
set style histogram cluster gap 1
set style fill solid border -1
set boxwidth 0.8
set xtic rotate by 90 scale 0
unset ytics
set y2tics rotate by 90

set y2label 'Ti_3SiC_2 content, wt{/Symbol\045}'  offset -2.5

#set xlabel ' '
set size 0.6, 1

set label 'Powder mixture' at graph 0.5, -0.1 centre rotate by 180


plot 'datos.txt' using 1:(-1):3 with labels rotate right, 'datos.txt' using 1:2 with boxes

и данные очень просты: 

# index, purity, name
1 98 Ti/Si/TiC
2 94 Ti/TiSi_2/TiC
3 93.6 Ti/Si/C
4 92 Ti/SiC/TiC
5 93 Ti/SiC/C
6 98 Ti/Si/C + Al

и я ожидаю выходное изображение, подобное рисунку 4 (стр. 6) главы 1 этой ссылки: https://books.google.es/books?id=zNWeBQAAQBAJ&printsec=frontcover&hl=es#v=onepage&q&f=false

Но мой выходной файл не имеет отношения к этому изображению.

Любая идея / помощь?

Заранее спасибо.

1 Ответ

1 голос
/ 07 мая 2019

Для ваших данных вам не нужна гистограмма.Горизонтальные полосы достаточно.Вместо поворота графика со стилем черчения with boxes вы можете использовать стиль черчения with boxxyerror.Убедитесь, что ваш разделитель данных - TAB, или поместите ваши метки в "...". 

### horizontal bars
reset session
set colorsequence classic
set datafile separator "\t"

$Data <<EOD
# index, purity, name
1   98  Ti/Si/TiC
2   94  Ti/TiSi_2/TiC
3   93.6    Ti/Si/C
4   92  Ti/SiC/TiC
5   93  Ti/SiC/C
6   98  Ti/Si/C + Al
EOD

unset key
set xlabel "Ti_2SiC_2 content, wt%" enhanced
set xrange [90:100]
set ylabel "Powder mixture"
unset ytics
set yrange [0:7]

set style fill solid 1.0
plot $Data u 2:1:(0):2:($1-0.4):($1+0.4):1 with boxxyerror lc variable,\
    '' u 2:1:3 with labels offset 1,0 left
### end of code

Результат:

enter image description here

...