Applescript для дублирования и переименования - PullRequest
Новая
       22

Applescript для дублирования и переименования

1 голос
/ 20 мая 2019

Я пытаюсь создать AppleScript для дублирования одного файла в новом месте при переименовании файла.Я зацикливался на переименовании файла.

Я попытался установить "со свойствами", установить псевдонимы, и я все еще получаю ошибки.

tell application "Finder"
    set JobName to text returned of (display dialog "Please Enter Crate Name:" default answer "Job_Name")
    set loc to alias "Volumes:MusicExt:_Serato_:Subcrates:"
    set templatefile to alias "Volumes:MusicExt:Serato_Working:crate-template.crate"

    duplicate file templatefile to loc --> with properies {name:JobName}
    duplicate file templatefile to loc --> with properies {name:"10. Pre-CMY.m3u"}
 end tell

1 Ответ

1 голос
/ 20 мая 2019
  • Прежде всего пути HFS начинаются всегда с имени диска, а не с Volumes.
  • Во-вторых, никогда не ставьте ключевое слово file перед спецификатором alias

В Finder вам нужно выполнить два шага: продублируйте файл и переименуйте его.
Воспользуйтесь возвращаемым значением duplicate, которое является дублированным файлом. 

tell application "Finder"
    set JobName to text returned of (display dialog "Please Enter Crate Name:" default answer "Job_Name")
    -- In this case just HFS string paths are preferable
    set loc to "MusicExt:_Serato_:Subcrates:"
    set templatefile to "MusicExt:Serato_Working:crate-template.crate"

    set duplicatedFile to duplicate file templatefile to folder loc
    set name of duplicatedFile to JobName -- (& ".crate") is there no file extension??
 end tell

Примечание: with properties работает только с командой make.

...