Excel VBA для выбора PivotField и связанных значений данных с этой строкой PivotField

Question

Я хочу выбрать все ячейки данных, связанные с одним конкретным PivotField, из элементов строки, как мне это сделать?

Мои данные выглядят примерно так:

          Sum of x  Sum of y  Sum of z
Class1       2.5        1         2
   *Name1    *1        *0        *0
   *Name2    *1        *1        *1
   *Name3    *.5       *0        *1
Class2       3.8       2.6        2
   *NameA    *1        *1        *0
   *NameB   *0.8       *0        *1
   *NameC    *1       *0.6       *0 
   *NameD    *1        *1        *1

ТеперьЯ только хочу выбрать данные с * перед и выполнить условное форматирование - если значение ячейки меньше 1, выделите ячейку.Если оно больше 1, выделите его другим цветом.У меня возникают проблемы при выборе нужного диапазона данных, как описано выше.

Вот код попытки: (ошибка: объект не поддерживает это свойство или метод)

Sub formatPivotTable()

Dim pt As PivotTable
Dim pf As PivotField
Dim pi As PivotItem

Set pt = ActiveSheet.PivotTables("test")

Set pf = pt.PivotFields("Name").PivotItems.DataRange.Select (error: object doesnt support this property or method)

With pf.DataRange
    .Interior.ColorIndex = 6
    .FormatConditions.Delete
    .FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:="=1"
    With .FormatConditions(1)
        .Interior.ColorIndex = 3

    End With
    .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=1"
    With .FormatConditions(2)
        .Interior.ColorIndex = 4
    End With
End With

End Sub

Любая помощь приветствуется.

Answer 1

Надеюсь, это то, что вы ищете.

Код ниже:

1. Перебирает каждый pivotItem в "Имя" pivotField и создает namesRange, используя Union. namesRange соответствует $B$5:$B$7,$B$9:$B$12 на скриншоте.
2. Затем использует Intersect, namesRange.EntireRow и DataBodyRange всей сводной таблицы, чтобы получить condFormRange. condFormRange соответствует $B$5:$D$7,$B$9:$D$12 на скриншоте.

Оттуда условное форматирование такое, какое у вас уже есть.

Sub FormatPivotTable()
    Dim pt As PivotTable
    Set pt = ActiveSheet.PivotTables("test")

    Dim pf As PivotField
    Set pf = pt.PivotFields("Name")

    Dim pi As PivotItem
    Dim namesRange As Range

    For Each pi In pf.PivotItems
        If namesRange Is Nothing Then
            Set namesRange = pi.DataRange
        Else
            Set namesRange = Union(namesRange, pi.DataRange)
        End If
    Next pi

    Debug.Print namesRange.Address ' returns $B$5:$B$7,$B$9:$B$12

    If Not namesRange Is Nothing Then
        Dim condFormRange As Range
        Set condFormRange = Intersect(namesRange.EntireRow, pt.DataBodyRange)
        Debug.Print condFormRange.Address ' returns $B$5:$D$7,$B$9:$D$12

        With condFormRange
            .Interior.ColorIndex = 6
            .FormatConditions.Delete
            .FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:="=1"

            With .FormatConditions(1)
                .Interior.ColorIndex = 3
            End With

            .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=1"

            With .FormatConditions(2)
                .Interior.ColorIndex = 4
            End With
        End With
    End If
End Sub