Я пытаюсь сделать кнопку включения и выключения светодиода, но вместо этого она просто гаснет - PullRequest
Новая
       51

Я пытаюсь сделать кнопку включения и выключения светодиода, но вместо этого она просто гаснет

1 голос
/ 20 мая 2019

Я начал с кода, чтобы светодиод включался при нажатии кнопки.Это сработало.Но затем я попытался настроить его так, чтобы кнопка работала как при включении / выключении, когда вы нажимаете ее только один раз для переключения между состояниями.

Светодиод работает со старым кодом (ниже), поэтому я не думаю, что это проблема с проводкой.К вашему сведению, я пропустил функцию настройки, так же, как когда я заставил ее мигать. 

// constants won't change. They're used here to
// set pin numbers:
const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin

// variables will change:
int buttonState = 0;         // variable for reading the pushbutton status
int switcher = 0;

void loop() {
  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed.
  // if it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    if (switcher = 0) {
      switcher = 1;
      delay(500);
    }
    else if (switcher = 1) {
      switcher = 0;
      delay(500);
    }
  }
  if (switcher == 1) {
    digitalWrite(ledPin, HIGH);
  }
  /*
  else {
    digitalWrite(ledPin, LOW);
  }
  */

}

Ответы [ 2 ]

1 голос
/ 20 мая 2019

На основании https://www.arduino.cc/en/Tutorial/StateChangeDetection

/*
  State change detection (edge detection)

  Often, you don't need to know the state of a digital input all the time, but
  you just need to know when the input changes from one state to another.
  For example, you want to know when a button goes from OFF to ON. This is called
  state change detection, or edge detection.

  This example shows how to detect when a button or button changes from off to on
  and on to off.

  The circuit:
  - pushbutton attached to pin 2 from +5V
  - 10 kilohm resistor attached to pin 2 from ground
  - LED attached from pin 13 to ground (or use the built-in LED on most
    Arduino boards)

  created  27 Sep 2005
  modified 30 Aug 2011
  by Tom Igoe

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/ButtonStateChange
*/

// this constant won't change:
const int  buttonPin = 2;    // the pin that the pushbutton is attached to
const int ledPin = 13;       // the pin that the LED is attached to

// Variables will change:
int buttonPushCounter = 0;   // counter for the number of button presses
int buttonState = 0;         // current state of the button
int lastButtonState = 0;     // previous state of the button

void setup() {
  // initialize the button pin as a input:
  pinMode(buttonPin, INPUT);
  // initialize the LED as an output:
  pinMode(ledPin, OUTPUT);
  // initialize serial communication:
  Serial.begin(9600);
}


void loop() {
  // read the pushbutton input pin:
  buttonState = digitalRead(buttonPin);

  // compare the buttonState to its previous state
  if (buttonState != lastButtonState) {
    // if the state has changed, increment the counter
    if (buttonState == HIGH) {
      // if the current state is HIGH then the button went from off to on:
      buttonPushCounter++;
      Serial.println("on");
      Serial.print("number of button pushes: ");
      Serial.println(buttonPushCounter);
    } else {
      // if the current state is LOW then the button went from on to off:
      Serial.println("off");
    }
    // Delay a little bit to avoid bouncing
    delay(50);
  }
  // save the current state as the last state, for next time through the loop
  lastButtonState = buttonState;


  // turns on the LED every two button pushes by checking the modulo of the
  // button push counter. the modulo function gives you the remainder of the
  // division of two numbers:
  if (buttonPushCounter % 2 == 0) {
    digitalWrite(ledPin, HIGH);
  } else {
    digitalWrite(ledPin, LOW);
  }

}
0 голосов
/ 20 мая 2019

Delay используется только если вы хотите, чтобы вся система остановилась.Он также используется в учебных целях в начале карьеры Arduino.В реальном приложении вы будете использовать библиотеку задержек или синхронизацию.Если вы используете задержку в приложении, вы не можете прочитать событие кнопки HIGH, это означает, что кнопка может быть прочитана только в 501 мсек точно после 500 мс задержки, у вас будет окно 1 мс или меньше, что почтиневозможно для человека времени.В любом случае вам стоит взглянуть на пример " Blink Without Delay " от Arduino.

Также вы должны использовать подтягивающий резистор для кнопок или объявить INPUT_PULLUP для pinMode в настройке, чтобы избежать отскока, см. Пример ниже.

Вот как вы решаете код: 

// defined constants in Arduino don’t take up any program memory space on the chip.
#define buttonPin 2;
#define ledPin 13;

// bytes are half the size of int's, but restricted to a max value of 255
byte value;
byte oldValue = 0;
byte state = 0;

void setup()
{
  pinMode(buttonPin , INPUT_PULLUP);
  pinMode(ledPin, OUTPUT);
}

void loop()
{
  value = digitalRead(buttonPin );
  if(value && !oldValue) // same as if(button == high && oldValue == low)
  {
    //we have a new button press
    if(state == 0) // if the state is off, turn it on
    {
      digitalWrite(ledPin, HIGH);
      state = 1;
    }
    else // if the state is on, turn it off
    {
      digitalWrite(ledPin, LOW);
      state = 0;
    }
    oldValue = 1;
  }
  else if(!value && oldValue) // same as if(button == low && oldValue == high)
  {
    // the button was released
    oldValue = 0;
  }
}
...