При написании VBA я не могу получить две конкретные ошибки для прохождения

Question

Я получаю недопустимое использование кода в моей первой строке и получаю сбой метода 'Range' объекта '_Worksheet' при вводе моего объекта в качестве диапазона.Кто-нибудь может помочь?

Sub SplitandFilterSheet()

    Dim SplitOrderNum As Range

    Sheets("Sum To Line Item").Select

    Set SplitOrderNum = Range("SplitOrderNum")

    For Each cell In SplitOrderNum
        Sheets("Sum To Line Item").Copy After:=Worksheets(Sheets.Count)
        ActiveSheet.Name = cell.Value

        With ActiveWorkbook.Sheets(cell.Value).Range("OrderData")
            .AutoFilter Field:=2, Criteria1:="<>" & cell.Value, Operator:=xlFilterValues
            .Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete
        End With

        ActiveSheet.AutoFilter.ShowAllData
    Next cell
End Sub

Answer 1

Попробуйте этот код, прочитайте комментарии внутри и найдите <<<< Настройте эту строку >>>:

Sub SplitandFilterSheet()

    ' Declare objects
    Dim sourceSheet As Worksheet
    Dim targetSheet As Worksheet
    Dim splitOrderNum As Range
    Dim sourceCell As Range

    ' Declare other variables
    Dim sourceSheetName As String
    Dim sourceRangeName As String
    Dim targetSheetName As String
    Dim targetRangeName As String

    Dim lastSheetHidden As Boolean


    ' <<< Customize this >>>
    sourceSheetName = "Sum To Line Item"
    sourceRangeName = "SplitOrderNum"
    targetRangeName = "OrderData"

    ' Initialize the source sheet
    Set sourceSheet = ThisWorkbook.Sheets(sourceSheetName)

    ' Initialize the range (Add full qualifier to the current workbook, sheet and range)
    Set splitOrderNum = sourceSheet.Range(sourceRangeName)

    ' Get if last sheet is visible in current workbook
    lastSheetHidden = Not ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count).Visible
    ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count).Visible = True

    For Each sourceCell In splitOrderNum
        ' Copy the source worksheet
        sourceSheet.Copy After:=Worksheets(ThisWorkbook.Sheets.Count)
        ' Rename the new worksheet
        Sheets(ThisWorkbook.Sheets.Count).Name = sourceCell.Value
        ' Reference to the added worksheet
        Set targetSheet = ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count)

        With targetSheet.Range(targetRangeName)
            .AutoFilter Field:=2, Criteria1:="<>" & sourceCell.Value, Operator:=xlFilterValues
            .Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete
        End With

        ' Check this next line if this should point to the orderdata range too (?)
        targetSheet.AutoFilter.ShowAllData

    Next sourceCell

    ' Return the last sheet visible state
    If lastSheetHidden = False Then
        ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count).Visible = Not lastSheetHidden
    End If

End Sub