Как пройти через любой XML и заменить определенное значение с помощью XSLT

Question

Я хочу создать XSLT-преобразование, которое проходит через любую XML-структуру и заменяет определенное значение. Например:

Входной XML:

<?xml version="1.0" encoding="UTF-8"?>
<Node1>
    <Node2>
        <Node3>
            <Tag1>1</Tag1>
            <Tag2>2</Tag2>
            <Tag3>3</Tag3>
        </Node3>
    </Node2>
</Node1>

Допустим, я хочу заменить любое значение "2" на "1"

Ожидаемый выходной XML:

<?xml version="1.0" encoding="UTF-8"?>
<Node1>
    <Node2>
        <Node3>
            <Tag1>1</Tag1>
            <Tag2>1</Tag2>
            <Tag3>3</Tag3>
        </Node3>
    </Node2>
</Node1>

Я уже пытался выполнить цикл с помощью операторов xsl: for-each и xsl: if, но он не работает:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template  match="/"> 
        <xsl:copy-of select=".">
            <xsl:for-each select=".">
                <xsl:if test="xsl:value-of select = '2'">
                    xsl:value-of select = '1'
                </xsl:if>
            </xsl:for-each>
        </xsl:copy-of> 
    </xsl:template>
</xsl:stylesheet>

Я предполагаю, что xsl: value-of part не верна, но я действительно не знаю, как получить доступ к значению Tag в условии.

Answer 1

Это кажется странным требованием.Предполагая, что «значение» означает текстовый узел в элементе (а не значение атрибута), вы можете сделать следующее:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="text()[.='2']">
    <xsl:text>1</xsl:text>
</xsl:template>

</xsl:stylesheet>