CMake GLOB_RECURSE не работает должным образом - PullRequest
Новая
       21

CMake GLOB_RECURSE не работает должным образом

0 голосов
/ 17 июня 2019

У меня есть структура папок со следующим 

mainfolder/
          folderA/a.dll
          folderB/subFolderB/subsubFolderB/b.dll
          folderC/c.dll

Я хочу получить все библиотеки DLL, которые находятся в основной папке, включая подпапки.

Я не получаю никакого результата, выполняя GLOB_RECURSE в основной папке. Библиотеки определенно есть до того, как код достигнет вызова GLOB_RECURSE. Вот что я делаю: 

set(THIRDPARTY_INSTALLFOLDER ${CMAKE_BINARY_DIR}/3rdparty/${CMAKE_BUILD_TYPE})
file(GLOB_RECURSE THEDLLS ${THIRDPARTY_INSTALLFOLDER} "*.dll")
message(STATUS ${THEDLLS})

поэтому ${THIRDPARTY_INSTALLFOLDER} - это основная папка , о которой я упоминал выше. Вывод сообщения с ${THEDLLS} просто ничего.

ПРИМЕЧАНИЕ: После очистки / перестроения / запуска cmake снова он находит библиотеки DLL, которые находятся в папке A, но не более (ничего в папке B или папке C). И снова, библиотеки DLL определенно создаются до вызова GLOB_RECURSE, но НЕ до вызова CMakeLists.txt.

РЕДАКТИРОВАТЬ: Вот рабочий пример. Имейте в виду, что загружается довольно большая библиотека OpenCV . Я использовал это, потому что моя основная проблема заключается в том, что библиотеки DLL создаются в разных структурах папок, в зависимости от того, какую систему вы создали, поэтому копирование библиотек DLL кажется мне таким сложным. Чтобы запустить этот пример, просто создайте CMakeLists.txt и main.cpp со следующим содержимым:

CMakeLists.txt 

cmake_minimum_required(VERSION 3.13)
project(DownloadAndLinkOpenCV)
###First I define where to output .exe and DLLs if there were any
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/build/${CMAKE_BUILD_TYPE}/bin)
###This defines the INSTALL dir of OpenCV(Where to put DLLs etc.)
set(THIRDPARTY_INSTALLFOLDER ${CMAKE_BINARY_DIR}/3rdparty/${CMAKE_BUILD_TYPE})

####function to download and build external project from https://stackoverflow.com/questions/17446981/cmake-externalproject-add-and-findpackage
function (build_external_project target git_repo git_tag cmake_custom_args)
    message(STATUS "building ${target} this might take a while...")
    set(trigger_build_dir ${CMAKE_BINARY_DIR}/3rdparty_${target})
    file(MAKE_DIRECTORY ${trigger_build_dir} ${trigger_build_dir}/build)

    set(CMAKE_LIST_CONTENT "
    cmake_minimum_required(VERSION 3.13)
    include(ExternalProject)
    ExternalProject_Add(${target}
        GIT_REPOSITORY ${git_repo}
        GIT_TAG        ${git_tag}
        PREFIX ${target}
        CMAKE_ARGS ${cmake_custom_args}
    )
ExternalProject_Add_StepTargets(${target} build install)
add_custom_target(trigger_${target})
add_dependencies(trigger_${target} ${target})
")

file(WRITE ${trigger_build_dir}/CMakeLists.txt "${CMAKE_LIST_CONTENT}")

execute_process(COMMAND ${CMAKE_COMMAND} .. -G${CMAKE_GENERATOR}
    WORKING_DIRECTORY ${trigger_build_dir}/build
    )
execute_process(COMMAND ${CMAKE_COMMAND} --build .
    WORKING_DIRECTORY ${trigger_build_dir}/build
    )
message(STATUS "finished building ${target}!")
endfunction()

####build OpenCV
set(OPENCV_GIT_REPO https://github.com/opencv/opencv.git)
set(OPENCV_TAG 3.4.6)
set(OPENCV_CMAKE_ARGS "-DCMAKE_INSTALL_PREFIX=${THIRDPARTY_INSTALLFOLDER} -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}")
build_external_project(opencv ${OPENCV_GIT_REPO} ${OPENCV_TAG} ${OPENCV_CMAKE_ARGS})
####finished building OpenCV now that it is built we can use find_package
set(OpenCV_DIR ${THIRDPARTY_INSTALLFOLDER})
find_package(OpenCV REQUIRED)

####finished 3rdparty building
add_executable(TestApplication main.cpp)
target_link_libraries(TestApplication ${OpenCV_LIBS})

####Now I want to copy the DLLs which were built but GLOB_RECURSE will not give me the name of all DLLs
####I specifically used OpenCV since the main problem is that it creates a more complex folder structure
####in the INSTALL dir. In my case it creates /x64/vc15/...the dlls (x64 is architecture and vc15 the compiler)
####I don't want to hard code the x64/vc15 string because anyone should be able to built it with any compiler
file(GLOB_RECURSE THEDLLS ${THIRDPARTY_INSTALLFOLDER} "*.dll")
message(STATUS ${THEDLLS})

main.cpp 

#include <iostream>
#include <opencv2/core.hpp>
int main()
{
    cv::Mat Mat;
    std::cout<<"Hello World"<<std::endl;
}

Обратите внимание, что я использую Qt Creator в качестве IDE и компилятор Visual Studio 2017

1 Ответ

0 голосов
/ 18 июня 2019

После некоторых дополнительных мыслей я нашел очень простое решение. Я сделал неправильный вызов GLOB_RECURSE. Вот фрагмент кода, который работает и делает то, что я хочу: Копирование всех библиотек DLL в папке в определенный каталог 

####get all dlls in a folder including sub folders
####The wrong call was this one: 
####file(GLOB_RECURSE THEDLLS ${THIRDPARTY_INSTALLFOLDER} "*.dll")
file(GLOB_RECURSE THEDLLS "${THIRDPARTY_INSTALLFOLDER}/*.dll")
#####This will copy the DLLs to a folder
foreach(currentDLL ${THEDLLS})
    add_custom_command(TARGET TestApplication POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E copy
                    ${currentDLL}
                    ${CMAKE_RUNTIME_OUTPUT_DIRECTORY})
endforeach(currentDLL)

Дело в том, что GLOB_RECURSE выполняет полное сопоставление с образцом пути.

...