Oracle - отправка электронной почты с вложением Excel

Question

Я хочу отправить файл Excel с электронной почтой, используя PLSQL

Я использую XLSX_BUILDER_PKG для создания файлов Excel, и все работает отлично. Он создает файлы Excel правильно.

https://github.com/commi235/xlsx_builder/blob/master/xlsx_builder_pkg.pks

declare
excel BLOB := empty_blob();

begin
  xlsx_builder_pkg.clear_workbook;
  xlsx_builder_pkg.new_sheet;
  xlsx_builder_pkg.cell( 1, 4, 'Start date:', p_alignment => xlsx_builder_pkg.get_alignment( p_horizontal => 'center' ),p_fillId => xlsx_builder_pkg.get_fill('solid','99CCFF'), p_fontId => xlsx_builder_pkg.get_font( 'Calibri',p_bold => true,p_fontsize => 12) );
  xlsx_builder_pkg.cell( 1, 5, sysdate,p_fillId => xlsx_builder_pkg.get_fill('solid','99CC99'),p_alignment => xlsx_builder_pkg.get_alignment( p_horizontal => 'center' ) );
  xlsx_builder_pkg.cell( 4, 4, 'End date:', p_alignment => xlsx_builder_pkg.get_alignment( p_horizontal => 'center' ),p_fillId => xlsx_builder_pkg.get_fill('solid','99CCFF'), p_fontId => xlsx_builder_pkg.get_font( 'Calibri',p_bold => true,p_fontsize => 12) );
  xlsx_builder_pkg.cell( 4, 5, sysdate ,p_fillId => xlsx_builder_pkg.get_fill('solid','99CC99'),p_alignment => xlsx_builder_pkg.get_alignment( p_horizontal => 'center' ));

  xlsx_builder_pkg.save('EXCEL_FILES', 'emp8.xls');
  excel := xlsx_builder_pkg.finish;


 test_send_mail('my@mail.com',
                 'my@mail.com',
                 'Test',
                 'Test',
                 'excel.xls',
                 'application/vnd.openxmlformats-officedocument.spreadsheetml.sheet',
                 excel,
                 'myhost',
                 25); 
end;

Затем я хочу отправить файл Excel в качестве вложения, я использовал функцию xlsx_builder_pkg.finish, чтобы получить BLOB, и когда я отправляю электронную почту, я получаю ее с вложением, но файл Excel не работает.

CREATE OR REPLACE PROCEDURE test_send_mail (p_to          IN VARCHAR2,
                                       p_from        IN VARCHAR2,
                                       p_subject     IN VARCHAR2,
                                       p_text_msg    IN VARCHAR2 DEFAULT NULL,
                                       p_attach_name IN VARCHAR2 DEFAULT NULL,
                                       p_attach_mime IN VARCHAR2 DEFAULT NULL,
                                       p_attach_blob IN BLOB DEFAULT NULL,
                                       p_smtp_host   IN VARCHAR2,
                                       p_smtp_port   IN NUMBER DEFAULT 25)
AS
  l_mail_conn   UTL_SMTP.connection;
  l_boundary    VARCHAR2(50) := '----=*#abc1234321cba#*=';
  l_step        PLS_INTEGER  := 12000; -- make sure you set a multiple of 3 not higher than 24573
BEGIN
  l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);
  UTL_SMTP.helo(l_mail_conn, p_smtp_host);
  UTL_SMTP.mail(l_mail_conn, p_from);
  UTL_SMTP.rcpt(l_mail_conn, p_to);

  UTL_SMTP.open_data(l_mail_conn);

  UTL_SMTP.write_data(l_mail_conn, 'Date: ' || TO_CHAR(SYSDATE, 'DD-MON-YYYY HH24:MI:SS') || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'To: ' || p_to || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'From: ' || p_from || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || p_subject || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'Reply-To: ' || p_from || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'MIME-Version: 1.0' || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'Content-Type: multipart/mixed; boundary="' || l_boundary || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

  IF p_text_msg IS NOT NULL THEN
    UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);
    UTL_SMTP.write_data(l_mail_conn, 'Content-Type: text/plain; charset="iso-8859-1"' || UTL_TCP.crlf || UTL_TCP.crlf);

    UTL_SMTP.write_data(l_mail_conn, p_text_msg);
    UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);
  END IF;

  IF p_attach_name IS NOT NULL THEN
    UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);
    UTL_SMTP.write_data(l_mail_conn, 'Content-Type: ' || p_attach_mime || '; name="' || p_attach_name || '"' || UTL_TCP.crlf);
    UTL_SMTP.write_data(l_mail_conn, 'Content-Disposition: attachment; filename="' || p_attach_name || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

    FOR i IN 0 .. TRUNC((DBMS_LOB.getlength(p_attach_blob) - 1 )/l_step) LOOP
      UTL_SMTP.write_data(l_mail_conn, UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(DBMS_LOB.substr(p_attach_blob, l_step, i * l_step + 1))));
    END LOOP;

    UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);
  END IF;

  UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || '--' || UTL_TCP.crlf);
  UTL_SMTP.close_data(l_mail_conn);

  UTL_SMTP.quit(l_mail_conn);
END;

Я использовал разные типы MIME, но с 'application / vnd.openxmlformats-officedocument.spreadsheetml.sheet' у меня есть поврежденный файл (хэшированная информация) и с 'application / vnd.ms-excel'. есть файл, который я не могу открыть

Answer 1

Сравнивая это с кодом, который у меня есть, вы, похоже, пропускаете атрибут заголовка mime Content-Transfer-Encoding, который должен быть Base64

UTL_SMTP.write_data(l_mail_conn, 'Content-Transfer-Encoding: Base64' || UTL_TCP.crlf);

Еще одна вещь, которую следует учитывать в случае, если вложение становится действительно большим или код расширяется, чтобы разрешить несколько вложений, - это выполнить base64-кодирование перед открытием соединения с SMTP-сервером. В противном случае при преобразовании / записи вы можете получить тайм-аут на длительное сохранение сеанса.