Как переупорядочить токенизированный список в XSLT и одновременно прочитать два значения из него? - PullRequest
Новая
       30

Как переупорядочить токенизированный список в XSLT и одновременно прочитать два значения из него?

1 голос
/ 12 апреля 2019

У меня есть некоторый код (из GeoNetwork), который должен конвертировать Geography Markup Language (в XML) в GeoJSON. В настоящее время я пытаюсь добавить функциональность для чтения многоугольника, сформированного из posList, но мне трудно осмыслить / составить план того, что мне нужно сделать.

«Ввод» - это в основном строка, состоящая из набора координат. Так что это может выглядеть примерно так 

<gml:LinearRing gml:id="p21" srsName="http://www.opengis.net/def/crs/EPSG/0/4326">
    <gml:posList srsDimension="2">45.67 88.56 55.56 88.56 55.56 89.44 45.67 89.44</gml:posList>
 </gml:LinearRing >

(заимствовано из образца Википедии). Я могу разделить это в XSLT, используя что-то вроде 

<xsl:variable name="temp" as="xs:string*" select="tokenize(gml:LinearRing/gml:posList))" '\s'/>

что должно дать мне Temp =

('45.67', '88.56', '55.56', '88.56', '55.56', '89.44', '45.67', '89.44')

Проблема 1: GeoJSON хочет все в WGS 84 (EPSG 4326) и в порядке (long, lat) - но строгое соблюдение правил WGS 84 (которое, как я ожидаю, следует gml) означает, что координаты находятся в (lat, long) заказ - поэтому список необходимо переупорядочить. (Я думаю - это все еще очень меня смущает)

Проблема 2: GeoJSON хочет пары координат, но у меня просто есть список координат.

Моя текущая идея - сделать что-то вроде этого: 

<geom>
<xsl:text>{"type": "Polygon",</xsl:text>
<xsl:text>"coordinates": [
[</xsl:text>

<xsl:variable name="temp" as="xs:string*" select="tokenize(gml:LinearRing/gml:posList))" '\s'/>
<xsl:for-each select="$temp">
  <xsl:if test="position() mod 2 = 0">
    <xsl:value-of select="concat('[', $saved, ', ', ., ']')" separator=","/>
  </xsl:if>
  <xsl:variable name="saved" value="."/>
</xsl:for-each>
<xsl:text>]
] 
}</xsl:text>
</geom>

но я не уверен, позволит ли XSL непрерывно писать переменную, подобную этой, и может ли быть лучшее / более эффективное решение проблемы. (У меня большой опыт работы с MATLAB, где я бы быстро, если не эффективно, решал эту проблему, используя циклы for)

В идеале я бы получил вывод, аналогичный 

<geom>
{"type": "Polygon",
"coordinates": [
  [
  [88.56, 45.67],
  [88.56, 55.56],
  [89.44, 55.56],
  [89.44, 45.67]
  ]
]
}
</geom>

(Существует целый ряд других проблем, связанных с определением, является ли многоугольник правым или левосторонним, я думаю)

Ответы [ 3 ]

1 голос
/ 12 апреля 2019

Эта таблица стилей с любым вводом (не используется) 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
                xmlns:my="dummy"
                exclude-result-prefixes="my">
   <xsl:template match="/">
      <xsl:sequence select="
            my:reverseByTuple(
                  ('45.67', '88.56', '55.56', '88.56', '55.56', '89.44', '45.67', '89.44')
            )"/>
   </xsl:template> 
   <xsl:function name="my:reverseByTuple">
        <xsl:param name="items"/>
        <xsl:sequence 
            select="if (empty($items))
                    then ()
                    else ($items[2], $items[1], my:reverseByTuple($items[position()>2]))"
                    />
    </xsl:function>
</xsl:stylesheet>

выход 

88.56 45.67 88.56 55.56 89.44 55.56 89.44 45.67

Я действительно не понимаю, почему вы сериализуете JSON, а не используете хорошо документированную библиотеку, такую ​​как функции в XSLT 3.0 ... Но просто для удовольствия, эта таблица стилей 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
                xmlns:my="dummy"
                exclude-result-prefixes="my">
   <xsl:template match="/">
      <xsl:value-of 
        select="
          my:encloseWithBracket(
            my:reverseByTupleEncloseWithBracket(
              ('45.67', '88.56', '55.56', '88.56', '55.56', '89.44', '45.67', '89.44')
            )
          )"/>
   </xsl:template> 
   <xsl:function name="my:reverseByTupleEncloseWithBracket">
        <xsl:param name="items"/>
        <xsl:sequence 
            select="if (empty($items))
                    then ()
                    else (my:encloseWithBracket(($items[2],$items[1])),
                          my:reverseByTupleEncloseWithBracket($items[position()>2]) )"
                    />
    </xsl:function>
   <xsl:function name="my:encloseWithBracket">
        <xsl:param name="items"/>
        <xsl:value-of select="concat('[',string-join($items,','),']')"/>
    </xsl:function>
</xsl:stylesheet>

выход 

[[88.56,45.67],[88.56,55.56],[89.44,55.56],[89.44,45.67]]
1 голос
/ 12 апреля 2019

XSLT 3 с поддержкой XPath 3.1 может представлять JSON как карты / массивы и сериализовать их как JSON, чтобы вы могли вычислить карту XPath из вашей последовательности координат: 

serialize(
    map { 
      'type' : 'polygon', 
      'coordinates' : array { 
          let $seq := tokenize(gml:LinearRing/gml:posList, '\s+') 
          return $seq[position() mod 2 = 0]![., let $p := position() return $seq[($p - 1) * 2 + 1]] 
         }
    },
    map { 'method' : 'json', 'indent' : true() }
)

https://xsltfiddle.liberty -development.net/gWvjQfu/1

Чтобы получить числа JSON в массивах, используйте let $seq := tokenize(., '\s+')!number() вместо let $seq := tokenize(gml:LinearRing/gml:posList, '\s+').

Если у вас есть доступ к процессору XSLT 3, например, SaxonPE или EE или Altova, поддерживающие функции более высокого порядка, можно уменьшить до 

        serialize(
          map {
            'type': 'polygon',
            'coordinates': array {
                let $seq := tokenize(gml:LinearRing/gml:posList, '\s+'),
                    $odd := $seq[position() mod 2 = 1],
                    $even := $seq[position() mod 2 = 0]
                return
                    for-each-pair($odd, $even, function ($c1, $c2) {
                        [$c2, $c1]
                    })
            }
          }, 
          map {
            'method': 'json',
            'indent': true()
          }
        )
0 голосов
/ 12 апреля 2019

Вы можете использовать следующую таблицу стилей XSLT-2.0, чтобы получить желаемый результат.Он использует функцию xsl:analyze-string для разделения значений в двух кортежах.Шаблон включает обработку ошибок и удаляет целевое пространство имен gml из выходных данных с помощью exclude-result-prefixes="gml".Возможно, вам придется настроить пути XML шаблона и выражение xsl:analyze-string.Но я думаю, что вы можете справиться с этим. 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:gml="http://www.opengis.net/def/crs/EPSG/0/4326" exclude-result-prefixes="gml">
    <xsl:output method="xml" omit-xml-declaration="yes" />

    <xsl:template match="/">
<geom><xsl:text>
{"type": "Polygon",
"coordinates": [
  [
</xsl:text>
        <xsl:analyze-string select="gml:LinearRing/gml:posList" 
        regex="\s*(\d\d)\.(\d\d)\s+(\d\d)\.(\d\d)\s*"> 
            <xsl:matching-substring>
                <xsl:value-of select="concat('    [',regex-group(3),'.', regex-group(4),', ',regex-group(1),'.', regex-group(2),']&#xa;')"/>
            </xsl:matching-substring>
            <xsl:non-matching-substring>
                <xsl:message terminate="yes">=============================&#xA;=== ERROR: Invalid input! ===&#xA;=============================</xsl:message>
            </xsl:non-matching-substring>
        </xsl:analyze-string>
<xsl:text>  ]
]
}
</xsl:text>
</geom>
    </xsl:template>

</xsl:stylesheet>

Его вывод: 

<geom>
{"type": "Polygon",
"coordinates": [
  [
    [88.56, 45.67]
    [88.56, 55.56]
    [89.44, 55.56]
    [89.44, 45.67]
  ]
]
}
</geom>%
...