Подсчитать результаты запроса в переменной - PullRequest
Новая
       33

Подсчитать результаты запроса в переменной

0 голосов
/ 25 апреля 2019

Я преобразовал текстовый файл для доступа.

Скажем, мой запрос доступа будет иметь 

Data.Employeeid, Data.Location, Data.Hours, Location.Percent, Location.Union, Data.Date

Теперь запрос к этому набору данных будет возвращать дубликаты. Для дальнейшей обработки данных мне бы хотелось, чтобы подсчитывалось поле data.date (по одному на каждый дубликат).

Я могу понять это с помощью переменной.

Кто-нибудь знает, как можно разрешить одному и тому же запросу select подсчитывать количество дубликатов (на основе employeeid)?

По сути, в этом запросе есть 3 соединения, и это вызывает у меня затруднения.

1 Ответ

0 голосов
/ 25 апреля 2019

Вы можете использовать мою RowNumber функцию, которая позволяет группировать: 

' Builds consecutive row numbers in a select, append, or create query
' with the option of a initial automatic reset.
' Optionally, a grouping key can be passed to reset the row count
' for every group key.
'
' 2018-08-23. Gustav Brock, Cactus Data ApS, CPH.
'
Public Function RowNumber( _
    ByVal Key As String, _
    Optional ByVal GroupKey As String, _
    Optional ByVal Reset As Boolean) _
    As Long

    ' Uncommon character string to assemble GroupKey and Key as a compound key.
    Const KeySeparator      As String = "¤§¤"
    ' Expected error codes to accept.
    Const CannotAddKey      As Long = 457
    Const CannotRemoveKey   As Long = 5

    Static Keys             As New Collection
    Static GroupKeys        As New Collection
    Dim Count               As Long
    Dim CompoundKey         As String

    On Error GoTo Err_RowNumber

    If Reset = True Then
        ' Erase the collection of keys and group key counts.
        Set Keys = Nothing
        Set GroupKeys = Nothing
    Else
        ' Create a compound key to uniquely identify GroupKey and its Key.
        ' Note: If GroupKey is not used, only one element will be added.
        CompoundKey = GroupKey & KeySeparator & Key
        Count = Keys(CompoundKey)

        If Count = 0 Then
            ' This record has not been enumerated.
            '
            ' Will either fail if the group key is new, leaving Count as zero,
            ' or retrieve the count of already enumerated records with this group key.
            Count = GroupKeys(GroupKey) + 1
            If Count > 0 Then
                ' The group key has been recorded.
                ' Remove it to allow it to be recreated holding the new count.
                GroupKeys.Remove (GroupKey)
            Else
                ' This record is the first having this group key.
                ' Thus, the count is 1.
                Count = 1
            End If
            ' (Re)create the group key item with the value of the count of keys.
            GroupKeys.Add Count, GroupKey
        End If
        ' Add the key and its enumeration.
        ' This will be:
        '   Using no group key: Relative to the full recordset.
        '   Using a group key:  Relative to the group key.
        ' Will fail if the key already has been created.
        Keys.Add Count, CompoundKey
    End If

    ' Return the key value as this is the row counter.
    RowNumber = Count

Exit_RowNumber:
    Exit Function

Err_RowNumber:
    Select Case Err
        Case CannotAddKey
            ' Key is present, thus cannot be added again.
            Resume Next
        Case CannotRemoveKey
            ' GroupKey is not present, thus cannot be removed.
            Resume Next
        Case Else
            ' Some other error. Ignore.
            Resume Exit_RowNumber
    End Select

End Function

Полностью документировано в моей статье:

Последовательные строки в Microsoft Access

Также для загрузки включена демонстрационная версия.

Вход в систему не требуется; просто найдите ссылку: Нажмите, чтобы прочитать статью полностью.

...