Сортировка по нескольким полям с критериями в Grails - PullRequest
Новая
       29

Сортировка по нескольким полям с критериями в Grails

8 голосов
/ 20 августа 2009

У меня следующий запрос, который можно отсортировать по "raceDate" и "raceNo" asc. Я могу понять, как сортировать по одному полю, а не по двум, какие-либо идеи? 

def list = {
        params.max = Math.min( params.max ? params.max.toInteger() : 20,  100) 
        params.offset = params?.offset?.toInteger() ?: 0
        params.sort = "raceDate"
        params.order = params?.order ?: "asc"

        def results = Race.createCriteria().list(
                max: params.max,
                offset: params.offset,
                sort: params.sort, 
                order: params.order
                ) {
            and {
                if (params.raceNo && params.raceNo != '')
                    eq("raceNo", params.raceNo.toInteger())
                if (params.country && params.country != '')
                    eq("country", params.country)
                if (params.venue && params.venue != '')
                    eq("venue", params.venue)
                if (params.raceType && params.raceType != '')
                    eq("raceType", params.raceType)
                if (params.surface && params.surface != '')
                    eq("surface", params.surface)
                if (params.officialGoing && params.officialGoing != '')
                    eq("officialGoing", params.officialGoing)

                if (params.raceDateStart_year && params.raceDateStart_month && params.raceDateStart_day 
                        && params.raceDateEnd_year && params.raceDateEnd_month && params.raceDateEnd_day) {
                    String startInput = "${params.raceDateStart_year}/${params.raceDateStart_month}/${params.raceDateStart_day}"
                    Date startDate = jodaFormatter.parseDateTime(startInput).toDate();
                    String endInput = "${params.raceDateEnd_year}/${params.raceDateEnd_month}/${params.raceDateEnd_day}"
                    Date endDate = jodaFormatter.parseDateTime(endInput).toDate();  

                    between("raceDate", startDate, endDate)
                }
            }
        }

        [ raceInstanceList:results, raceInstanceTotal:results.totalCount, params:params ]
}

1 Ответ

4 голосов
/ 20 августа 2009

Примерно так должно работать: 

def results = Race.createCriteria().list(
                max: params.max,
                offset: params.offset,
                sort: params.sort, 
                ) {
                order('raceDate', 'asc')
                order('raceNo', 'asc')
                and {
                    if (params.raceNo && params.raceNo != '')
                        eq("raceNo", params.raceNo.toInteger())
                ...
...