Входной дисковый пакетный файл - PullRequest
0 голосов
/ 19 марта 2019

Я хотел бы запустить следующую команду: "diskpart / s my_batch.bat"

содержание командного файла:

rescan
select disk 1
online disk

Я хотел бы изменить выбранный диск, чтобы прийти от ввода пользователя Как мне это сделать? Я попробовал:

"выберите диск% 1"

как в пакетных файлах но это не сработало, как разрешить части диска принимать пользовательский ввод

1 Ответ

1 голос
/ 19 марта 2019

Создание файла .script на лету (то же место / имя, что и у пакета)
и передайте его Diskpart. Самоподъемный (только частично проверенный).

:: Q:\Test\2019\03\19\SO_55242922.cmd
@echo off & setlocal EnableExtensions DisableDelayedExpansion
net file 1>nul 2>&1 || (powershell -ex unrestricted -Command ^
"Start-Process -Verb RunAs -FilePath '%comspec%' -ArgumentList '/c %~f0 %*'"
  goto :eof)
:: Put code here that needs elevation

if "%~1" equ "" goto :ListDisk

( Echo rescan
  Echo select disk %1
  Echo online disk
  Echo Exit
) > "%~dpn0.script"

Goto :ExecViewOutput

:ListDisk
( Echo list disk
  Echo Exit
) > "%~dpn0.script"

:ExecViewOutput

diskpart /s "%~dpn0.script" >"%~dpn0.log"

type "%~dpn0.log"
Pause
:: optionally delete the script/log file
:: Del %~dpn0.log" "%~dpn0.script"
Exit /B 0
...