Почему почтовый код не работает

Question

Set objCDOSYSMail = Server.CreateObject("CDO.Message") 
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

Set Flds = objCDOSYSCon.Fields
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "any mail"
Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "any password"
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "any server"
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")  = 25
Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 1

Flds.update

Set objCDOSYSMail.Configuration = objCDOSYSCon 

objCDOSYSMail.From = "any mail"
objCDOSYSMail.To = "any mailid"
'' // objCDOSYSMail.CC = "any mailid"
objCDOSYSMail.Bcc = "any mailid"    
objCDOSYSMail.Subject = "feed back"                     
objCDOSYSMail.HTMLBody = strBody

objCDOSYSMail.Send

Set objCDOSYSMail = Nothing

'' // Response.redirect("thank.html")
response.Write("saved")

Answer 1

Изменение

Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 1

до

Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

1 - идет поиск через каталог раскладки 2 - отправка по SMTP

Глядя на другие параметры, которые вы явно пытаетесь отправить через порт 25.

Answer 2

Попробуйте это

    Dim objCDOSYSMail
    Dim objCDOSYSCon
    Dim Flds

    Set objCDOSYSMail = Server.CreateObject("CDO.Message") 
    Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration") 
    Set Flds = objCDOSYSCon.Fields

    With Flds
    .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

    .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "any server"

    .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")  = 25

    .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1

    .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "any mail"

    .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "any password"

    .Update

    End With

    Set objCDOSYSMail.Configuration = objCDOSYSCon 

    'Sending The Email
    With objCDOSYSMail
    .From = "any mail"
        .To = "any mailid"
        .Subject = "feed back"                                             
        .HTMLBody = "my Message"
        .Send

    End With

    'Disposing Objects

    Set objCDOSYSMail = Nothing
    Set objCDOSYSCon = Nothing
    Set Flds = Nothing

Если вы не получили никакой ошибки, проверьте журнал ошибок на сервере. Убедитесь, что сервер может пересылать электронную почту на почтовый сервер (smtpserver). Это можно сделать, выполнив быстрый сеанс TELNET с веб-сервера на сервер электронной почты. Некоторые SMTP-серверы также выполняют обратный DNS в домене отправителей. Это может звучать глупо, но также проверьте имя пользователя и пароль.

ПРИМЕЧАНИЕ. Ваш вопрос был отклонен, поскольку вы не указали четко свое намерение. В следующий раз будьте "УКАЗАННЫ", а не "УНИКАЛЬНЫ" (как большое море). Большинство людей, которые тусуются здесь, либо профессионалы, либо пытаются ими быть, так что, по крайней мере, старайтесь быть такими.

Answer 3

Вы можете использовать для этого библиотеку с открытым исходным кодом ajaxed . Он обнаруживает компонент, и вам не нужно об этом беспокоиться.

Забудьте о проблеме выбора правильный компонент электронной почты (установка и настраиваю его). Ajaxed делает это для вы. Он проверяет, какие компоненты установлен на сервере и использует "лучший. Пожалуйста, обратитесь к API для посмотреть, какие компоненты в настоящее время поддерживается. Как эта страница была написана Jmail, ASPEmail и CDOSYS были поддерживается.

Вот учебник о том, как отправить электронное письмо .