Показатели в Google Sheets с различными критериями «отличается от» в одной строке добавляют +1 значение

Question

Я пытаюсь подсчитать все значения, отличные от некоторых определенных критериев, в одной строке на листе Google, который подается через форму Google, но в конечном счете отображается «1».

Строка, с которой я рассчитываю, соответствует вопросу с несколькими вариантами ответов, в котором есть опция «прочее», поэтому пользователь может вводить другие значения, а я пытаюсь подсчитать количество «других» значений в строке..

Я пробовал нормальный счет и мог, но когда вы используете <>, он заканчивает счет до бесконечности, если вы хотите проверить диапазон B2: B (B1 - заголовок), поэтому я использовал структуру этого:

=COUNTIFS(query('FORMS RESPONSES'!B2:B,"<>TYPE A"), 
query('FORMS RESPONSES'!B2:B,"<>TYPE B"),
query('FORMS RESPONSES'!B2:B,"<>TYPE C"),
query('FORMS RESPONSES'!B2:B,"<>TYPE D"),
query('FORMS RESPONSES'!B2:B,"<>TYPE E"),
)

Предполагая, что канал имеет 1 ответ для A, B, C и ни одного для D, E и 2 других записей со случайными значениями, ответ должен быть = 2, но он дает мне только =1

У меня есть это:

=COUNTIFS(
query(datos!B2:B,"<>PC Tipo 1 (HP)")
,query(datos!B2:B,"<>PC Tipo 2 (Lenovo)")
,query(datos!B2:B,"<>PC Tipo 3 (Dell)")
,query(datos!B2:B,"<>Laptop Tipo 1 (Lenovo)")
,query(datos!B2:B,"<>Laptop Tipo 2 (Thinkpad)")
,query(datos!B2:B,"<>Tel Cel.")
)

VG:

Пример ввода данных для B2: B будет:

• PC Tipo1 (HP)
• ПК Tipo 2 (Lenovo)
• ПК Tipo 3 (Dell)
• Ноутбук Tipo 1 (Lenovo)
• сервер HP
• Projector

Таким образом, всего 6 записей, из которых 2 являются «другим» видом, который я пытаюсь сосчитать (сервер HP и Projector).И все же результат дает мне =1

Answer 1

или вы можете сделать это так:

=ARRAYFORMULA(COUNTA(datos!B2:B)-
 SUM(COUNTIF(datos!B2:B, {"PC Tipo 1 (HP)",
                          "PC Tipo 2 (Lenovo)",
                          "PC Tipo 3 (Dell)",
                          "Laptop Tipo 1 (Lenovo)",
                          "Laptop Tipo 2 (Thinkpad)",
                          "Tel Cel."})))

Answer 2

вы получаете 1 как одну ошибку. сделай так:

=COUNTA(QUERY(datos!B2:B, "where not B contains 'PC Tipo 1 (HP)' 
                             and not B contains 'PC Tipo 2 (Lenovo)'
                             and not B contains 'PC Tipo 3 (Dell)'
                             and not B contains 'Laptop Tipo 1 (Lenovo)'
                             and not B contains 'Laptop Tipo 2 (Thinkpad)'
                             and not B contains 'Tel Cel.'", 0))