SAS: изменить цвет и толщину контрольной метки в proc gplot - PullRequest
Новая
       100

SAS: изменить цвет и толщину контрольной метки в proc gplot

1 голос
/ 19 марта 2019

Я пытаюсь изобразить различные уровни зарплаты на игольном графике, и мне нужна контрольная линия.Следующий код предоставляет эту контрольную линию, но линия того же цвета, что и иглы, и слишком тонкая.Есть ли способ изменить это? 

SYMBOL1
    INTERPOL=NEEDLE
    HEIGHT=10pt
    VALUE=NONE
    LINE=1
    WIDTH=2
    CV = _STYLE_
;
Axis1
    STYLE=1
    WIDTH=1
    MINOR=NONE
    REFLABEL=(j=c color = red width = 5 '');
;
Axis2
    STYLE=1
    WIDTH=1
    MINOR=NONE
;
TITLE;
TITLE1 "Bootstrap: Needle Plot of log salary";
PROC GPLOT 
    DATA = sashelp.baseball
    ;
    PLOT logsalary * name /
        VAXIS = AXIS1
        HAXIS = AXIS2
        VREF  = 4
    ;
RUN; QUIT;

1 Ответ

1 голос
/ 20 марта 2019

Цвет и ширина контрольной линии (ей) определяются списками перечисления в параметрах VREF, CVREF и WVREF оператора PLOT. Ярлыки и цвета контрольных линий должны быть вручную выровнены с аналогичными списками перечисления в операторе AXIS.

Дополнительный контроль над процессом построения может быть сделан с наборами данных аннотации. В частности, можно указать аннотации, которые будут нарисованы после того, как процедура завершит рисование, а результат визуализации будет отображаться поверх вывода процедуры.

Пример 

SYMBOL1 INTERPOL=NEEDLE HEIGHT=10pt VALUE=NONE LINE=1WIDTH=2 CV = _STYLE_ ;

Axis1 order = 0 to 10 STYLE=1 WIDTH=1 MINOR=NONE
    REFLABEL = 
      ( j=c color=RED height=4 "HELLO"     /* labels for two reference lines */
        j=l color=BLUE height=3 "EIGHT"  
      );
Axis2 STYLE=1 WIDTH=1 MINOR=NONE ;

TITLE;
TITLE1 "Bootstrap: Needle Plot of log salary";

options mprint;

DATA anno;
   %annomac;
   when = 'After';
   %system (1,2,4)
   %line (0,1, 100,1, GREEN, 0, 6)
   %label (30, 1.2, "LABEL AFTER", GREEN, 0, 0, 4, , B)
/* %LABEL (x, y, text-string, color, angle, rotate, size, style, position); */
RUN;

PROC GPLOT 
    DATA = sashelp.baseball(obs=20)
    ANNO = anno
    ;
    PLOT logsalary * name /
        VAXIS = AXIS1
        HAXIS = AXIS2

           VREF = ( 4  8 )         /* axial data value of reference lines */
          WVREF = ( 4  6 )         /* Width and colors of reference lines */
          CVREF = ( RED BLUE )
    ;
run;quit;
...