Предупреждение о всплывающем скрипте в .bat

Question

Я хочу создать всплывающее предупреждение, чтобы каждый раз что-то запоминалось при включении ноутбука.

Кто-то сказал мне, что я могу использовать скрипт bat / batch.

Я пробовал это:

@echo off
echo x=msgbox("Blahblahblah" ,0, "Alert") >> msgbox.vbs

start msgbox.vbs

И это работает только тогда, когда я нажимаю на файл, сохраненный на моем рабочем столе. Но я не знаю, что делать, чтобы он работал автоматически при включении ноутбука. Я имею в виду, я хочу видеть всплывающее сообщение каждый раз, когда я его включаю.

Answer 1

Возможные ответы на ваш вопрос:

1. Создайте ярлык для командного файла в каталоге автозагрузки, C:\Users\%UserName%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup.
2. Запустите пакетный файл из реестра, HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run.
3. Использовать планировщик задач, "%__AppDir__%taskschd.msc" /s.

Поскольку этот сайт предназначен для кода и не содержит ссылок на ваши исследования, я позволю вам самим рассмотреть все вышеперечисленное.

Кроме того, вы также можете использовать powershell из вашего пакетного файла , в отличие от vbscript :

@Echo Off
Rem Message to display.
Set "message=Blahblahblah"
Rem Window title to display.
Set "caption=Reminder"
Rem Displayed icon. Use either Enumerator or ValueType.
Rem  0  None                  No symbols.
Rem 16  Error|Hand|Stop       White X in a circle with a red background.
Rem 32  Question              Question mark in a circle. Do not use, included only for backward compatibility.
Rem 48  Exclamation|Warning   Exclamation point in a triangle with a yellow background.
Rem 64  Asterisk|Information  Lowercase letter i in a circle.
Set "icon=Information"
Rem Displayed button. Use either Enumerator or ValueType.
Rem 0  OK           OK button. 
Rem 1  OKCancel     OK and Cancel buttons.
Rem 3  YesNoCancel  Yes, No, and Cancel buttons.
Rem 4  YesNo        Yes and No buttons.
Set "button=0"

PowerShell -NoProfile^
 "[Reflection.Assembly]::LoadWithPartialName('System.Windows.Forms')|Out-Null;"^
 "[System.Windows.Forms.MessageBox]::Show('%message%','%caption%','%button%','%icon%')"