Сообщение об ошибке - «ожидается закрывающая скобка» при инициализации списка - PullRequest
Новая
       22

Сообщение об ошибке - «ожидается закрывающая скобка» при инициализации списка

0 голосов
/ 22 мая 2019

Я определил собственный список черепах, который называется color-affinity.Каждая из 14 записей в этом списке состоит из именованного цвета netlogo и соответствующего случайного числа вплоть до 5.

Я пытаюсь инициализировать этот список в процедуре настройки, вызывая функцию: setup-turtle-color-affinity.

Я работаю над Netlogo 6.1 (последняя версия).Код ниже. 

turtles-own [
  color-affinity
]

...
..
.

to setup
  clear-all
  create-turtles population
  setup-turtle-color-affinity
  setup-patches
  reset-ticks
end

...
..
.

to setup-turtle-color-affinity
  ask turtles
  [ setup-color-affinity ]
end

to setup-color-affinity
  [
   ; Here, I want to set up the list so that each turtle gets a random named netlogo color and a corresponding random "affinity" score of up to 5. However, whenever I try this (and I've tried various combinations of syntax) it gives me an error saying "closing bracket expected".
  ]
end

1 Ответ

2 голосов
/ 22 мая 2019

Для получения полезного ответа может потребоваться немного больше деталей - например, как настроен ваш список цветов? В Netlogo названия цветов читаются просто как числа: grey равно 5, red равно 15 и т. Д. Какой формат вы предпочитаете для color-affinity?

Если вы ищете список пар списков для каждой черепахи, где каждая пара является значением цвета и значением сходства, возможно, что-то подобное может работать для вас: 

turtles-own [
  color-affinity
]

to setup
  ca

  let color-values ( range 5 145 10 )

  crt 5 [
    set color-affinity map [ c -> list c ( random 4 + 1 ) ] color-values
    show color-affinity
  ]
  reset-ticks
end

Выход: 

(turtle 1): [[5 4] [15 3] [25 2] [35 4] [45 2] [55 1] [65 2] [75 1] [85 2] [95 3] [105 3] [115 1] [125 3]]
(turtle 3): [[5 2] [15 2] [25 2] [35 1] [45 2] [55 4] [65 4] [75 4] [85 3] [95 2] [105 1] [115 2] [125 2]]
(turtle 2): [[5 2] [15 4] [25 1] [35 1] [45 1] [55 4] [65 3] [75 2] [85 4] [95 1] [105 4] [115 4] [125 2]]
(turtle 0): [[5 1] [15 1] [25 3] [35 4] [45 4] [55 1] [65 4] [75 2] [85 1] [95 4] [105 1] [115 1] [125 1]]
(turtle 4): [[5 3] [15 3] [25 4] [35 4] [45 2] [55 2] [65 4] [75 1] [85 2] [95 3] [105 1] [115 4] [125 3]]

Изменить:

Я не знаю, как автоматически получить названия цветов (не говоря уже о том, что их нет!) - возможно, вам придется сделать что-то вроде table подхода к расширению: 

extensions [ table ]

globals [ color-table ]

to setup-color-table
  set color-table table:make
  let color-names [ 
    "gray" "red" "orange" "brown" "yellow" 
    "green" "lime" "turquoise" "cyan" "sky"
    "blue" "violet" "magenta" "pink" 
  ]
  let color-values ( range 5 145 10 )
  ( foreach color-values color-names [
    [ cv cn ] ->
    table:put color-table cv cn 
    ]
  )

  show table:get color-table 15
  show table:get color-table 65
  show table:get color-table 115
end

Выход: 

observer: "red"
observer: "lime"
observer: "violet"
...