Добавление значения одной ячейки в тело письма через Excel

Question

У меня есть макрос, который автоматически создает электронное письмо, прикрепляет два листа из моей книги в виде вложений, а затем отправляет эти листы по электронной почте утвержденным людям.Я хотел бы выяснить, как получить значение ячейки в «C3» из листа «Инструкции» в тело создаваемого им электронного письма.Я пробовал несколько разных программ, но пока не нашел, как это сделать.

Sub Labor_Material_16009()
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim Sourcewb As Workbook
Dim Destwb As Workbook
Dim TempFilePath As String
Dim TempFileName As String
Dim OutApp As Object
Dim OutMail As Object

With Application
    .ScreenUpdating = False
    .EnableEvents = False
End With

Set Sourcewb = ActiveWorkbook

With Sourcewb
    Set theactivewindow = ActiveWindow
    Set tempwindow = .NewWindow
    .Sheets(Array("16009 Labor", "16009 Material")).Copy
End With

tempwindow.Close

Set Destwb = ActiveWorkbook

With Destwb
    If Val(Application.Version) < 12 Then
        'You use Excel 97-2003
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        'You use Excel 2007-2016
        Select Case Sourcewb.FileFormat
        Case 51: FileExtStr = ".xlsm": FileFormatNum = 52
        Case 52:
            If .HasVBProject Then
                FileExtStr = ".xlsm": FileFormatNum = 52
            Else
                FileExtStr = ".xlsm": FileFormatNum = 52
            End If
        Case 56: FileExtStr = ".xlsm": FileFormatNum = 52
        Case Else: FileExtStr = ".xlsm": FileFormatNum = 52
        End Select
    End If
End With

With Destwb.Sheets(1).UsedRange
.Cells.Copy
.Cells.PasteSpecial xlPasteValues
.Cells(1).Select
End With
Application.CutCopyMode = False

TempFilePath = Environ$("temp") & "\"
TempFileName = "16009 - " & Sourcewb.Name & " " & Format(Now, "dd-mmm-yy")

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

With Destwb
    .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
    On Error Resume Next
    With OutMail
        .To = ""
        .CC = ""
        .BCC = ""
        .Subject = "16009 Labor and Material Report"
        .Body = "Please see the attached"
        .Attachments.Add Destwb.FullName
        'You can add other files also like this
        '.Attachments.Add ("C:\test.txt")
        .Send   'or use .Display
    End With
    On Error GoTo 0
    .Close savechanges:=False
End With

Kill TempFilePath & TempFileName & FileExtStr

Set OutMail = Nothing
Set OutApp = Nothing

With Application
    .ScreenUpdating = True
    .EnableEvents = True
End With
End Sub

Answer 1

Если вы хотите сохранить свою стандартную подпись:

With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "16009 Labor and Material Report"
    '.Body = NOT HERE
    .Attachments.Add Destwb.FullName

    Dim wdDoc As Word.Document
    Set wdDoc = .GetInspector.WordEditor
    If Not wdDoc Is Nothing Then
        With wdDoc.Range
            .Collapse wdCollapseStart
            .InsertBefore "Please see the attached" & vbCrLf
            .Collapse wdCollapseEnd
            .InsertAfter "Best wishes," & vbCrLf
            .Collapse wdCollapseStart
            Sourcewb.Worksheets("Instructions").Range("C3").Copy
            .Paste
            '.PasteAndFormat wdChartPicture
            '.PasteAndFormat wdFormatPlainText
        End With
    End If
    .Send   'or use .Display
End With

Answer 2

Я бы не использовал вложенные операторы WITH. Вы можете поместить значение любого диапазона в строковую переменную перед тем, как закрыть его и использовать позже в теле. Я также хотел бы избежать сокрытия ошибок, как вы делаете с кодом электронной почты. Обработайте ошибки или используйте обработчик ошибок, но не пропустите их.

ПОПРОБУЙТЕ:

Option Explicit

Sub Labor_Material_16009()
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    Dim theactivewindow As Window
    Dim tempwindow As Window
    Dim InstructionText As String
    With Sourcewb
        InstructionText = .Worksheets("Instructions").Range("C3").Value

        Set theactivewindow = ActiveWindow
        Set tempwindow = .NewWindow
        .Sheets(Array("16009 Labor", "16009 Material")).Copy
    End With

    tempwindow.Close

    Set Destwb = ActiveWorkbook

    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2016
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsm": FileFormatNum = 52
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsm": FileFormatNum = 52
                End If
            Case 56: FileExtStr = ".xlsm": FileFormatNum = 52
            Case Else: FileExtStr = ".xlsm": FileFormatNum = 52
            End Select
        End If
    End With

    With Destwb.Sheets(1).UsedRange
        .Value = .Value
    End With

    TempFilePath = Environ$("temp") & "\"
    TempFileName = "16009 - " & Sourcewb.Name & " " & Format(Now, "dd-mmm-yy")
    Dim tempFullPath As String
    tempFullPath = TempFilePath & TempFileName & FileExtStr

    With Destwb
        .SaveAs tempFullPath, FileFormat:=FileFormatNum
        .Close savechanges:=False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    With OutMail
        .To = ""
        .CC = ""
        .BCC = ""
        .Subject = "16009 Labor and Material Report"
        .Body = "Please see the attached" & vbNewLine & InstructionText
        .Attachments.Add tempFullPath
        'You can add other files also like this
        '.Attachments.Add ("C:\test.txt")
        .Send                                    'or use .Display
    End With

    Kill tempFullPath

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub