Самый чистый Perl-парсер для Makefile-подобных строк продолжения - PullRequest
Новая
       12

Самый чистый Perl-парсер для Makefile-подобных строк продолжения

3 голосов
/ 17 июня 2009

Perl-скрипт, который я пишу, должен проанализировать файл, имеющий строки продолжения, например Makefile. то есть строки, начинающиеся с пробела, являются частью предыдущей строки.

Я написал код ниже, но не чувствую, что он очень чистый или perl-ish (черт возьми, он даже не использует «redo»!)

Существует много крайних случаев: EOF в нечетных местах, однострочные файлы, файлы, которые начинаются или заканчиваются пустой строкой (или непустой строкой, или строкой продолжения), пустыми файлами. Все мои тесты (и код) здесь: http://whatexit.org/tal/flatten.tar

Можете ли вы написать чище, perl-ish, код, который проходит все мои тесты? 

#!/usr/bin/perl -w

use strict;

sub process_file_with_continuations {
    my $processref = shift @_;
    my $nextline;
    my $line = <ARGV>;

    $line = '' unless defined $line;
    chomp $line;

    while (defined($nextline = <ARGV>)) {
        chomp $nextline;
        next if $nextline =~ /^\s*#/;  # skip comments
        $nextline =~ s/\s+$//g;  # remove trailing whitespace
        if (eof()) {  # Handle EOF
            $nextline =~ s/^\s+/ /;
            if ($nextline =~ /^\s+/) {  # indented line
                &$processref($line . $nextline);
            }
            else {
                &$processref($line);
                &$processref($nextline) if $nextline ne '';
            }
            $line = '';
        }
        elsif ($nextline eq '') {  # blank line
            &$processref($line);
            $line = '';
        }
        elsif ($nextline =~ /^\s+/) {  # indented line
            $nextline =~ s/^\s+/ /;
            $line .= $nextline;
        }
        else {  # non-indented line
            &$processref($line) unless $line eq '';
            $line = $nextline;
        }
    }
    &$processref($line) unless $line eq '';
}

sub process_one_line {
    my $line = shift @_;
    print "$line\n";
}

process_file_with_continuations \&process_one_line;

Ответы [ 2 ]

6 голосов
/ 17 июня 2009

Как насчет того, чтобы вылить весь файл в память и обработать его с помощью регулярных выражений.Гораздо больше «perlish».Это проходит ваши тесты и намного меньше и аккуратнее: 

#!/usr/bin/perl

use strict;
use warnings;

$/ = undef;             # we want no input record separator.
my $file = <>;          # slurp whole file

$file =~ s/^\n//;       # Remove newline at start of file
$file =~ s/\s+\n/\n/g;  # Remove trailing whitespace.
$file =~ s/\n\s*#[^\n]+//g;     # Remove comments.
$file =~ s/\n\s+/ /g;   # Merge continuations

# Done
print $file;
3 голосов
/ 17 июня 2009

Если вы не против загрузить весь файл в память, то приведенный ниже код проходит тесты. Он сохраняет строки в массиве, добавляя каждую строку к предыдущей (продолжение) или в конце массива (другое). 

#!/usr/bin/perl

use strict;
use warnings;

my @out;

while( <>)
  { chomp;
    s{#.*}{};             # suppress comments
    next unless( m{\S});  # skip blank lines
    if( s{^\s+}{ })       # does the line start with spaces?
      { $out[-1] .= $_; } # yes, continuation, add to last line
    else 
      { push @out, $_;  } # no, add as new line
  }

$, = "\n";                # set output field separator
$\ = "\n";                # set output record separator
print @out;
...