Как отделить строку ABAP заглавными буквами (заглавными буквами)? - PullRequest
Новая
       5

Как отделить строку ABAP заглавными буквами (заглавными буквами)?

1 голос
/ 12 апреля 2019

В настоящее время у меня есть код в ABAP, который содержит строку, состоящую из нескольких слов, которые начинаются с заглавных букв / заглавных букв и между которыми нет пробелов, поэтому я должен разделить его на внутреннюю таблицу следующим образом:

ВХОД:

NameAgeAddress

ВЫХОД: 

Name

Age

Address

Ответы [ 5 ]

5 голосов
/ 12 апреля 2019

Вот самый короткий код, который я смог найти, который использует регулярное выражение в сочетании с SPLIT: 

SPLIT replace( val = 'NameAgeAddress' regex = `(?!^.)\u` with = ` $0` occ = 0 ) 
      AT ` ` 
      INTO TABLE itab.

Итак, replace преобразует «NameAgeAddress» в «Name Age Address», а SPLIT помещает 3 слова во внутреннюю таблицу.

Подробности:

  • (?!^.) сказать, что следующий символ для поиска (\ u) не должен быть первым символом
  • \u любая заглавная буква
  • $0 для замены найденной строки ($ 0) самой собой, перед которой ставится пробел
  • occ = 0 для замены всех вхождений
1 голос
/ 15 апреля 2019

Если вы не хотите или не можете использовать Regex, вот другое решение: 

DATA: lf_input             TYPE string VALUE 'NameAgeAddress',
      lf_offset            TYPE i,
      lf_current_letter    TYPE char1,
      lf_letter_in_capital TYPE char1,
      lf_word              TYPE string,
      lt_word              LIKE TABLE OF lf_word.

DO strlen( lf_input ) TIMES.
  lf_offset = sy-index - 1.
  lf_current_letter = lf_input+lf_offset(1).
  lf_letter_in_capital = to_upper( lf_current_letter ).
  IF lf_current_letter = lf_letter_in_capital.
    APPEND INITIAL LINE TO lt_word ASSIGNING FIELD-SYMBOL(<ls_word>).
  ENDIF.
  IF <ls_word> IS ASSIGNED. "if input string does not start with capital letter
    <ls_word> = <ls_word> && lf_current_letter.
  ENDIF.
ENDDO.
1 голос
/ 12 апреля 2019

Это легко с использованием регулярных выражений. Решение может выглядеть следующим образом. 

REPORT ZZZ.

DATA: g_string TYPE string VALUE `NameAgeAddress`.

DATA(gcl_regex) = NEW cl_abap_regex( pattern = `[A-Z]{1}[a-z]+` ).

DATA(gcl_matcher) = gcl_regex->create_matcher( text = g_string ).

WHILE gcl_matcher->find_next( ).
  DATA(g_match_result) = gcl_matcher->get_match( ).
  WRITE / g_string+g_match_result-offset(g_match_result-length).
ENDWHILE.
1 голос
/ 12 апреля 2019

К сожалению, оператор SPLIT в ABAP не допускает регулярное выражение в качестве выражения-разделителя.Поэтому мы должны использовать прогрессивное сопоставление, что немного неудобно в ABAP: 

report zz_test_split_capital.

parameters: p_input type string default 'NameAgeAddress' lower case.

data: output type stringtab,
      off    type i,
      moff   type i,
      mlen   type i.

while off < strlen( p_input ).
  find regex '[A-Z][^A-Z]*' 
    in section offset off of p_input 
    match offset moff match length mlen.
  if sy-subrc eq 0.
    append substring( val = p_input off = moff len = mlen ) to output.
    off = moff + mlen.
  else.
    exit.
  endif.
endwhile.

cl_demo_output=>display_data( output ).

Просто для сравнения, следующий оператор будет работать в Perl: 

my $input = "NameAgeAddress";
my @output = split /(?=[A-Z])/, $input; 
# gives @output = ('Name','Age','Address')
0 голосов
/ 15 апреля 2019

Для случаев, когда регулярные выражения просто перебивают, а обычный старый ABAP будет делать: 

DATA(str) = 'NameAgeAddress'.
IF str CA sy-abcde.
  DATA(off) = 0.
  DO.
    data(tailstart) = off + 1.
    IF str+tailstart CA sy-abcde.
      DATA(len) = sy-fdpos + 1.
      WRITE: / str+off(len).
      add len to off.
    ELSE.
      EXIT.
    ENDIF.
  ENDDO.
  write / str+off.
ENDIF.
...