XSLT отображает значения атрибута из диапазона

Question

Я новичок в xslt, и мне нужна ваша помощь.

Мой входной XML-файл выглядит так

<dataset>
    <item date="13days" />
    <item date="14days" />
    <item date="27days" />
</dataset>

И мой вывод должен выглядеть следующим образом

<dataset>
    <item date="1week" />
    <item date="2week" />
    <item date="3week" />
</dataset>

Карта будет выглядеть так:

0days<=1week<14days
14days<=2week<21days
21days<=3week<28days

Пока я просто знаю, как изменить конкретную дату, но мне нужны диапазоны.Вот моя попытка.

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:my="my:my">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<my:map>
<map>
<item from="13days" to="1week" />
<item from="14days" to="2week" />
<item from="27days" to="3week" />
</map>
</my:map>
<xsl:variable name="vMap" select="document('')/*/my:map/*/*"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="@maturity[. = document('')/*/my:map/*/*/@from]">
<xsl:attribute name="maturity">
<xsl:value-of select="$vMap[@from = current()]/@to"/>
</xsl:attribute>
</xsl:template>
</xsl:stylesheet>

Answer 1

Не могли бы вы просто:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="@date">
    <xsl:variable name="d" select="substring-before(., 'days')" />
    <xsl:attribute name="date">
        <xsl:choose>
            <xsl:when test="$d &lt; 14">1week</xsl:when>
            <xsl:when test="$d &lt; 21">2week</xsl:when>
            <xsl:when test="$d &lt; 28">3week</xsl:when>
        </xsl:choose>
    </xsl:attribute>
</xsl:template>

</xsl:stylesheet>

---

Или, если вы предпочитаете:

<xsl:template match="@date">
    <xsl:variable name="d" select="substring-before(., 'days')" />
    <xsl:attribute name="date">
        <xsl:choose>
            <xsl:when test="$d &lt; 14">1</xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="floor($d div 7)"/>
            </xsl:otherwise>
        </xsl:choose>
        <xsl:text>week</xsl:text>
    </xsl:attribute>
</xsl:template>