Отправка писем нескольким получателям с несколькими вложениями - PullRequest
Новая
       16

Отправка писем нескольким получателям с несколькими вложениями

0 голосов
/ 18 июня 2019

Я очень новичок в VBA и нашел в сети код, который отправляет электронные письма нескольким получателям, но может прикрепить только 1 файл на одно письмо. Я не могу найти код, который работает, в котором он идет в определенную папку и присоединяет все PDF-файлы, которые хранятся в папке и переходит в другую папку и делает то же самое для следующего получателя электронной почты. На рисунке показана структура листа, над которым я работаю. Я использую Office 365.

Лист Excel

Пожалуйста, помогите. Спасибо. 

Sub SendMail()

    ActiveWorkbook.RefreshAll

    Dim objOutlook As Object
    Dim objMail As Object
    Dim ws As Worksheet

    Set objOutlook = CreateObject("Outlook.Application")
    Set ws = ActiveSheet

On Error GoTo MyHandler

  For Each cell In ws.Range("A2:A2000")

    Set objMail = objOutlook.CreateItem(0)

        With objMail
            .To = cell.Value
            .Cc = "email@email.com"
            .Subject = cell.Offset(0, 1).Value
            .Body = cell.Offset(0, 2).Value
            .Attachments.Add cell.Offset(0, 3).Value
            .Display
        End With

        Set objMail = Nothing
    Next cell

    Set ws = Nothing
    Set objOutlook = Nothing

MyHandler:
MsgBox "Review email messages"

End Sub

Ответы [ 2 ]

0 голосов
/ 26 июня 2019

Это будет делать то, что вы хотите. 

Sub Send_Files()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim OutApp As Object
    Dim OutMail As Object
    Dim sh As Worksheet
    Dim cell As Range
    Dim FileCell As Range
    Dim rng As Range

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set sh = Sheets("Sheet1")

    Set OutApp = CreateObject("Outlook.Application")

    For Each cell In sh.Columns("B").Cells.SpecialCells(xlCellTypeConstants)

        'Enter the path/file names in the C:Z column in each row
        Set rng = sh.Cells(cell.Row, 1).Range("C1:Z1")

        If cell.Value Like "?*@?*.?*" And _
           Application.WorksheetFunction.CountA(rng) > 0 Then
            Set OutMail = OutApp.CreateItem(0)

            With OutMail
                .to = cell.Value
                .Subject = "Testfile"
                .Body = "Hi " & cell.Offset(0, -1).Value

                For Each FileCell In rng.SpecialCells(xlCellTypeConstants)
                    If Trim(FileCell) <> "" Then
                        If Dir(FileCell.Value) <> "" Then
                            .Attachments.Add FileCell.Value
                        End If
                    End If
                Next FileCell

                .Send  'Or use .Display
            End With

            Set OutMail = Nothing
        End If
    Next cell

    Set OutApp = Nothing
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Примечание: 

Make a list in Sheets("Sheet1") with :

In column A : Names of the people
In column B : E-mail addresses
In column C:Z : Filenames like this C:\Data\Book2.xls (don't have to be Excel files)

https://www.rondebruin.nl/win/s1/outlook/amail6.htm

0 голосов
/ 18 июня 2019

Вам необходимо повторить метод Attachment.Add для каждого файла в папке: 

Sub SendMail()

ActiveWorkbook.RefreshAll

Dim objOutlook As Object
Dim objMail As Object
Dim ws As Worksheet
Dim StrFile As String, StrPath As String

Set objOutlook = CreateObject("Outlook.Application")
Set ws = ActiveSheet

On Error GoTo MyHandler

For Each cell In ws.Range("A2:A2000")

   Set objMail = objOutlook.CreateItem(0)

    With objMail
        .To = cell.Value
        .Cc = "email@email.com"
        .Subject = cell.Offset(0, 1).Value
        .Body = cell.Offset(0, 2).Value
    End With

        StrPath = "D:\any_folder\" 
        StrFile = Dir(StrPath & "*.*")

        Do While Len(StrFile) > 0
            objMail.Attachments.Add StrPath & StrFile
            StrFile = Dir
        Loop  

    objMail.Display

    Set objMail = Nothing
Next cell

 Set ws = Nothing
 Set objOutlook = Nothing

MyHandler:
  MsgBox "Review email messages"

End Sub
...