Существует ли сокращенный способ сравнения диапазона ячеек с одним значением?

Question

Я хотел бы написать формулу, которая возвращает «True», если ВСЕ из определенного набора ячеек помечены знаком «X».Например, ниже ....

  A B C D E
1 X
2
3 X X
4   X
5     X

Один из способов проверить, что ВСЕ из этих значений имеют 'X', - по формуле ниже

=IF( AND(A1 = "X", A3 = "X", B3 = "X", B4 = "X", C5 = "X"), "True", "false")

Однако A3: B3аналогичная группировка, но оператор сравнения не признает, что для целей

=IF( AND(A1 = "X", A3:B3 = "X", B4 = "X", C5 = "X"), "True", "false")

Существует ли сокращенный способ сравнения диапазона ячеек с одним значением?

Answer 1

Вы также можете настроить шаблон на втором листе для ячеек, в которые вы хотите поместить X, а затем просто сравнить их:

=SUMPRODUCT((Sheet1!A1:C5=Sheet2!A1:C5)*(Sheet1!A1:C5="X"))

или для получения истинного / ложного результата:

=SUMPRODUCT((Sheet1!A1:C5=Sheet2!A1:C5)*(Sheet1!A1:C5="X"))=COUNTA(Sheet2!A1:C5)

Лист 2 (шаблон)

Лист 1 (для сравнения)

Answer 2

Хотя вы не можете использовать «фигурные скобки» (например, { и } для создания непрерывного массива ссылок на ячейки (например, {A1, A3:B3, B4, C5}), вы можете использовать фигурные скобки для создания массива строковых литералов (например, {"A1", "A3:B3", "B4", "C5"} иINDIRECT использует строковые литералы для определения диапазонов.

=SUM(COUNTIF(INDIRECT({"A1","A3:B3","B4","C5"}),"X"))

COUNTIF создает массив результатов из массива строковых литералов, интерпретируемых INDIRECT. Сумма SUM принимает этот массив результатов.

Это дает точный COUNTIF. Если вы хотите TRUE / FALSE, сравните его с результатом, если бы все они были X.

'any contiguous part of the discontiguous union can be grouped
=SUM(COUNTIF(INDIRECT({"A1","A3","B3","B4","C5"}),"X"))=5
=SUM(COUNTIF(INDIRECT({"A1","A3:B3","B4","C5"}),"X"))=5
=SUM(COUNTIF(INDIRECT({"A1","A3","B3:B4","C5"}),"X"))=5

Это , а не формулы массива.

Answer 3

В ячейке F1 Тип:

=IF(COUNTA(A1:E1)>=5, "True", "False")

В приведенном вами примере он должен вернуть false для всех из них.Он вернет true, если во всех ячейках есть X.

Answer 4

Используйте Control-Shift-Enter при вводе второго, чтобы использовать массивы, такие как отдельные значения.

=IF( AND(A1 = "X", A3:B3 = "X", B4 = "X", C5 = "X"), "True", "false") <ctrl-shift-enter>