Напечатайте некоторый текст в зависимости от номера страницы в формате pdf при генерации pdf через xslt и xsl: fo - PullRequest
Новая
       23

Напечатайте некоторый текст в зависимости от номера страницы в формате pdf при генерации pdf через xslt и xsl: fo

0 голосов
/ 20 марта 2019

Я использую следующие пространства имен lib / name для создания pdf из xml 

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:fo="http://www.w3.org/1999/XSL/Format"
    xmlns:fn="http://www.w3.org/2005/xpath-functions"
    xmlns:math="http://exslt.org/math" 
    xmlns:exslt="http://exslt.org/common"
    xmlns:str="http://exslt.org/strings"
    exclude-result-prefixes="exslt math str">

Мое требование заключается в том, что я хочу напечатать некоторый текст fo: block-container text будет напечатан на второй странице. 

<fo:block-container xsl:use-attribute-sets="section border_red">
    <fo:block xsl:use-attribute-sets="header">Product:</fo:block>                   
        <xsl:for-each select="ROWSET2/ROWSET2_ROW">
            <fo:block xsl:use-attribute-sets="paragraph indented"><xsl:value-of select="PRODUCTNAME"/></fo:block>
        </xsl:for-each>
        <!-- when page not first print something at the end of this block -->               
</fo:block-container>

Таким образом, печать внутри блока при переполнении блока на страницу 2ed, 3ed .., если блок завершен на первой странице, печать текста не требуется.

Попробовал "fo: retrieve-table-marker" 

                <fo:table>
                    <fo:table-header>
                        <fo:table-cell>
                            <fo:block xsl:use-attribute-sets="header">Product:
                            </fo:block>
                        </fo:table-cell>
                    </fo:table-header>

                    <fo:table-footer>
                        <fo:table-row>
                            <fo:table-cell>

                                <fo:retrieve-table-marker
                                    retrieve-class-name="test123" retrieve-boundary-within-table="table"
                                    retrieve-position-within-table="last-starting" />

                            </fo:table-cell>
                        </fo:table-row>
                    </fo:table-footer>

                    <fo:table-body>
                        <xsl:for-each select="ROWSET2/ROWSET2_ROW">
                            <xsl:choose>
                                <xsl:when test="position() != last()">
                                    <fo:table-row>
                                        <fo:marker marker-class-name="test123">To be continued...
                                        </fo:marker>
                                        <fo:table-cell>
                                            <fo:block xsl:use-attribute-sets="paragraph indented">
                                                <xsl:value-of select="PRODUCTNAME" />
                                            </fo:block>
                                        </fo:table-cell>
                                    </fo:table-row>
                                </xsl:when>
                                <xsl:otherwise>
                                    <fo:table-row>
                                        <fo:marker marker-class-name="test123"></fo:marker>
                                        <fo:table-cell>
                                            <fo:block xsl:use-attribute-sets="paragraph indented">
                                                <xsl:value-of select="PRODUCTNAME" />
                                                last
                                            </fo:block>
                                        </fo:table-cell>
                                    </fo:table-row>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:for-each>
                    </fo:table-body>
                </fo:table>

Ответы [ 2 ]

2 голосов
/ 20 марта 2019

Если ваше требование выводить специальный текст в конце страницы, когда fo: block-container разбивается на несколько страниц, такой функции нет в XSL 1.1 и расширениях от производителей процессоров XSL-FO (насколько я знаю).

Однако, если вы используете fo: table, fo: table-footer, fo: retrieve-table-marker и fo: marker с внешним правилом таблицы и записью без правила для одной строки, можно вывести специальныетекст, когда таблица разбивается на несколько страниц.

[XSL 1.1] 6.7.7 fo: нижний колонтитул таблицы

[XSL 1.1] 6.13.7 fo: retrieve-table-marker = "

[XSL 1.1] 6.13.5 fo: marker

См. пример снимка следующего поста в блоге (на японском языке):

Contin ー ブ ル の タ イ ト に に ((продолжение) "と す す． (3)

Frist Page

Second Page

Last Page

В этом примере «Переход к следующей странице» определяется в fo: marker в fo: table-cellи отображается в fo:нижний колонтитул fo: retrieve-table-marker.

Данные выборки: 

<?xml version="1.0" encoding="UTF-8"?>
<ROOT>
    <ROWSET2>
        <ROWSET2_ROW><PRODUCTNAME>Product1</PRODUCTNAME></ROWSET2_ROW>
        <ROWSET2_ROW><PRODUCTNAME>Product2</PRODUCTNAME></ROWSET2_ROW>
        ...
        <ROWSET2_ROW><PRODUCTNAME>Product24</PRODUCTNAME></ROWSET2_ROW>
        <ROWSET2_ROW><PRODUCTNAME>Product25</PRODUCTNAME></ROWSET2_ROW>
    </ROWSET2>
</ROOT>

Код примера: 

<xsl:template match="ROOT">
    <fo:table width="100%">
        <fo:table-header>
            <fo:table-cell>
                <fo:block xsl:use-attribute-sets="header">Product:
                </fo:block>
            </fo:table-cell>
        </fo:table-header>
        <fo:table-footer>
            <fo:table-row>
                <fo:table-cell>
                    <fo:retrieve-table-marker
                        retrieve-class-name="test123"/>
                </fo:table-cell>
            </fo:table-row>
        </fo:table-footer>
        <fo:table-body>
            <xsl:for-each select="ROWSET2/ROWSET2_ROW">
                <fo:table-row>
                    <fo:table-cell>
                        <fo:block xsl:use-attribute-sets="paragraph indented">
                            <xsl:choose>
                                <xsl:when test="position() = 1">
                                    <fo:marker marker-class-name="test123">
                                        <fo:block xsl:use-attribute-sets="indented" color="teal">To be continued...</fo:block>
                                    </fo:marker>
                                </xsl:when>
                                <xsl:when test="position() = last()">
                                    <fo:marker marker-class-name="test123"/>
                                </xsl:when>
                            </xsl:choose>
                            <xsl:value-of select="PRODUCTNAME" />
                            <xsl:if test="position()=last()">
                                <fo:inline> Last</fo:inline>
                            </xsl:if>
                        </fo:block>
                    </fo:table-cell>
                </fo:table-row>
            </xsl:for-each>
        </fo:table-body>
    </fo:table>
</xsl:template>

Результат выборки:

The sample PDF

0 голосов
/ 29 марта 2019

Найденное решение: следующий код работает с apache fop2.3

, когда я использовал <fo:inline> внутри <fo:marker>, тогда он работает. 

    <fo:table width="100%" xsl:use-attribute-sets="section border_red">
            <fo:table-header>
                <fo:table-cell>
                    <fo:block xsl:use-attribute-sets="header">Product:
                    </fo:block>
                </fo:table-cell>
            </fo:table-header>
            <fo:table-footer>
                <fo:table-row>
                    <fo:table-cell>
                        <fo:block text-align="end">
                        <fo:retrieve-table-marker
                            retrieve-class-name="test123"
                            retrieve-boundary-within-table="table"
                            retrieve-position-within-table="last-ending"
                            />
                        </fo:block>
                    </fo:table-cell>
                </fo:table-row>
            </fo:table-footer>
            <fo:table-body>
                <xsl:for-each select="ROWSET2/ROWSET2_ROW">
                    <fo:table-row>
                        <fo:table-cell>
                            <fo:block xsl:use-attribute-sets="paragraph indented">
                                <xsl:choose>
                                    <xsl:when test="position() = 1">
                                        <fo:marker marker-class-name="test123">                                        
                                            <fo:inline>To be continued...</fo:inline>
                                        </fo:marker>
                                    </xsl:when>
                                    <xsl:when test="position() = last()">
                                        <fo:marker marker-class-name="test123"/>
                                    </xsl:when>
                                </xsl:choose>
                                <xsl:value-of select="PRODUCTNAME" />
                                <xsl:if test="position()=last()">
                                    <fo:inline>Last..</fo:inline>
                                </xsl:if>
                            </fo:block>
                        </fo:table-cell>
                    </fo:table-row>
                </xsl:for-each>
            </fo:table-body>
        </fo:table>
...