Несоответствие типов для оператора 'mapObject' в Mule 3.8.0 DataWeave, который работал в 3.9.0

Question

Я создал проект API, который создает и отправляет запрос SOAP другому сервису на основе параметров, отправленных в API. Я по неосторожности построил проект в Mule 3.9.0 EE, когда наша производственная среда и среда разработки Mule - 3.8.0 EE. Проект отлично работает локально в 3.9.0 и работает в 3.8.0, пока не соберет запрос в Dataweave. В 3.8.0 сообщается о следующем исключении:

Root Exception stack trace:
com.mulesoft.weave.engine.ast.dynamic.UnexpectedOperationTypesException: Type mismatch for 'mapObject' operator
     found :array, :function
  required :object, :function

Я использую два Dataweaves для создания запроса. Первая строит подсказки, используемые в запросе SOAP, из параметров. Вторая создает запрос SOAP и вставляет подсказки.

Первый Dataweave:

%dw 1.0
%output application/json
---
[flowVars.parameterMap mapObject (value, key)->{
    PROMPT: {
        PSQueryName: "",
        UniquePromptName: key,
        FieldValue: value
    }
}]

Второй Dataweave:

%dw 1.0
%output application/xml encoding="UTF-8"
%namespace SOAP-ENV  http://schemas.xmlsoap.org/soap/envelope/
%namespace wsse  http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd
%namespace qas  http://xmlns.oracle.com/Enterprise/Tools/schemas/QAS_EXEQRY_SYNC_REQ_MSG.VERSION_1
%namespace qas1  http://xmlns.oracle.com/Enterprise/Tools/schemas/QAS_EXEQRY_SYNC_REQ.VERSION_1
---
{
    SOAP-ENV#Envelope: {
        SOAP-ENV#Header: {
            wsse#Security @(SOAP-ENV#mustUnderstand: "1"): {
                wsse#UsernameToken: {
                    wsse#Username: "someUsername",
                    wsse#Password @(Type: "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-username-token-profile-1.0#PasswordText"): "somePassword"
                }
            }
        },
        SOAP-ENV#Body: {
            qas#QAS_EXEQRY_SYNC_REQ_MSG: {
                qas1#QAS_EXEQRY_SYNC_REQ: {
                    QueryName: flowVars.queryName,
                    isConnectedQuery: "N",
                    OwnerType: flowVars.queryType,
                    BlockSizeKB: 0,
                    MaxRow: 0,
                    OutResultType: "webrowset",
                    OutResultFormat: "nonfile",
                    PROMPTS: payload.*PROMPT mapObject {
                        PROMPT: {
                            PSQueryName: $.PSQueryName when $.PSQueryName != "" otherwise {},
                            UniquePromptName: $.UniquePromptName,
                            FieldValue: $.FieldValue
                        }
                    }
                }
            }
        }
    }
}

В 3.9.0 Dataweave отлично преобразовал SOAP-запрос. В 3.8.0 возникла проблема с оператором PROMPTS: payload.*PROMPT mapObject во втором DataWeave.

Что изменилось в 3.9.0, что сделало эту работу правильно?

Как можно обойти эту проблему, чтобы решить эту проблему в 3.8.0?

Answer 1

Я решил это самостоятельно, скомбинировав два переплетения данных, и разделение этих двух оказалось ненужным.

Он не отвечает, какие изменения произошли в 3.9.0, что позволило ему работать в исходном проекте.

%dw 1.0
%output application/xml encoding="UTF-8"
%namespace SOAP-ENV  http://schemas.xmlsoap.org/soap/envelope/
%namespace wsse  http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd
%namespace qas  http://xmlns.oracle.com/Enterprise/Tools/schemas/QAS_EXEQRY_SYNC_REQ_MSG.VERSION_1
%namespace qas1  http://xmlns.oracle.com/Enterprise/Tools/schemas/QAS_EXEQRY_SYNC_REQ.VERSION_1
---
{
    SOAP-ENV#Envelope: {
        SOAP-ENV#Header: {
            wsse#Security @(SOAP-ENV#mustUnderstand: "1"): {
                wsse#UsernameToken: {
                    wsse#Username: "someUser",
                    wsse#Password @(Type: "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-username-token-profile-1.0#PasswordText"): "somePassword"
                }
            }
        },
        SOAP-ENV#Body: {
            qas#QAS_EXEQRY_SYNC_REQ_MSG: {
                qas1#QAS_EXEQRY_SYNC_REQ: {
                    QueryName: flowVars.queryName,
                    isConnectedQuery: "N",
                    OwnerType: flowVars.queryType,
                    BlockSizeKB: 0,
                    MaxRow: 0,
                    OutResultType: "webrowset",
                    OutResultFormat: "nonfile",
                    PROMPTS: flowVars.parameterMap mapObject (value, key)->{
                        PROMPT: {
                            PSQueryName: "",
                            UniquePromptName: key,
                            FieldValue: value
                        }
                    }
                }
            }
        }
    }
}