Perl6: сортировка хэша по значениям и использование kv - PullRequest
Новая
       41

Perl6: сортировка хэша по значениям и использование kv

7 голосов
/ 09 мая 2019

Я смотрю на следующие данные (в формате JSON) 

{
  "FValidation_pipelineMTHXT_v4.5.1_refLibV2": "concordance2/f",
  "FValidation_pipelineLPJL": "concordance2/c",
  "FCompetenceRuns": "concordance2/b",
  "FWGS": "concordance2/a",
  "Falidation_pipelineMTHXT": "concordance2/e",
  "FValidation_pipelineLPJL_v4.5.1_refLibV2": "concordance2/d"
}

и пытаюсь отсортировать по хеш-значению 

for %files.kv -> $key, $value {

дает необходимые данные, ноЯ хочу это отсортировано.Я пробовал около 20 различных методов, которые не работают 

for %files.sort.kv  -> ($key, $value) {

и 

for %files.sort: *.value.kv  -> ($key, $value) {

, которые были вдохновлены https://docs.perl6.org/routine/sort#(Map)_method_sort и так далее, но ни один из них не являетсяработает: (

Как мне отсортировать этот хеш по значению?

Ответы [ 2 ]

7 голосов
/ 10 мая 2019

.kv возвращает плоскую последовательность. 

my %h = (
  a => 3,
  b => 2,
  c => 1,
);

say %h.kv.perl;
# ("a", 3, "c", 1, "b", 2).Seq

Если вы ее отсортируете, то сделаете это, не сохранив ключ с соответствующим значением. 

say %h.kv.sort.perl;
# (1, 2, 3, "a", "b", "c").Seq

Итак, вы хотитечтобы отсортировать его до разбиения пар. 

# default sort order (key first, value second)
say %h.sort.perl;
# (:a(3), :b(2), :c(1)).Seq

say %h.sort: *.value;       # sort by value only (tied values are in random order)
# (:c(1), :b(2), :a(3)).Seq
say %h.sort: *.invert;      # sort by value first, key second
# (:c(1), :b(2), :a(3)).Seq
say %h.sort: *.kv.reverse;  # sort by value first, key second
# (:c(1), :b(2), :a(3)).Seq

После сортировки вы можете использовать его как последовательность объектов Pair: 

# default $_
for %h.sort: *.invert {
  say .key ~ ' => ' ~ .value
}

# extract as named attributes
for %h.sort: *.invert -> (:$key, :$value) {
  say "$key => $value"
}

# more explicit form of above
for %h.sort: *.invert -> Pair $ (:key($key), :value($value)) {
  say "$key => $value"
}

Или вы можете разделить пары после сортировки:
(обратите внимание на двухуровневую структуру.) 

say %h.sort(*.invert).map(*.kv).perl;
# (("c", 1).Seq, ("b", 2).Seq, ("a", 3).Seq).Seq
say %h.sort(*.invert)».kv.perl;
# (("c", 1).Seq, ("b", 2).Seq, ("a", 3).Seq).Seq

# default $_
for %h.sort(*.invert).map(*.kv) {
  say .key ~ ' => ' ~ .value
}

# extract inner positional parameters
for %h.sort(*.invert).map(*.kv) -> ($k,$v) {
  say "$k => $v"
}

# `».kv` instead of `.map(*.kv)`
for %h.sort(*.invert)».kv -> ($k,$v) {
  say "$k => $v"
}

Вы можете даже сплющить ее после разделения пары объектов. 

say %h.sort(*.invert).map(*.kv).flat.perl;
# ("c", 1, "b", 2, "a", 3).Seq
say %h.sort(*.invert)».kv.flat.perl;
# ("c", 1, "b", 2, "a", 3).Seq

for %h.sort(*.invert).map(*.kv).flat -> $k, $v {
  say "$k => $v"
}

for %h.sort(*.invert)».kv.flat -> $k, $v {
  say "$k => $v"
}

(Обратите внимание, что ».method отображает только один вызов метода. Чтобы отобразить два, вам нужно ».method1».method2, или просто используйте map .map(*.method1.method2).
Так что в ».kv.flat выше только .kv метод сопоставляется со значениями.)

7 голосов
/ 09 мая 2019 
my %hash = :a<z>, :b<y>, :c<x>;

for %hash.sort(*.value) {
    say $_.key;
    say $_.value;
}
...