Мне нужно переформатировать XML-файл в JSON с помощью XSLT, удалить теги заголовков и вставить массив] скобки

Question

Мне нужно преобразовать источник XML в указанный формат JSON. Для этого мне нужно удалить узлы заголовка, сохранить тело массива и инкапсулировать в []. Я преобразовал тело, но у меня возникают проблемы с удалением узлов заголовка и вставкой инкапсулирующего []

Это формат XML, который я получаю:

<?xml version="1.0" encoding="UTF-8"?>
<ns1:DDMRP_Parts xmlns:ns1="urn:za.sabmiller.com:supplychain:3rdp:transdata">
   <Part>
      <PartNumber>000096</PartNumber>
      <Location>A000</Location>
      <Description>TEST OF RAMIS</Description>
      <UnitOfMeasure>EA</UnitOfMeasure>
      <PartType>1</PartType>
      <FixedLeadTime>1</FixedLeadTime>
      <MaterialType>Filling &amp; Mixing Eq</MaterialType>
   </Part>
   <Part>
      <PartNumber>000096</PartNumber>
      <Location>A000</Location>
      <Description>TEST OF RAMIS</Description>
      <UnitOfMeasure>EA</UnitOfMeasure>
      <PartType>1</PartType>
      <FixedLeadTime>1</FixedLeadTime>
      <MaterialType>Filling &amp; Mixing Eq</MaterialType>
   </Part>
</ns1:DDMRP_Parts>

Я попытался использовать адаптер, предоставленный в SAP PI, чтобы выполнить преобразование, но это не учитывает полное тело массива. Я попытался переформатировать с использованием XSLT, но я не смог удалить внешние узлы и инкапсулировать с помощью []

Это мой XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
       <xsl:output method="text"/>
       <xsl:template match="/">{
        <xsl:apply-templates select="*"/>}
    </xsl:template>
       <!-- Object or Element Property-->
       <xsl:template match="*">
        "<xsl:value-of select="name()"/>" : <xsl:call-template name="Properties"/>
       </xsl:template>
       <!-- Array Element -->
       <xsl:template match="*" mode="ArrayElement">
              <xsl:call-template name="Properties"/>
       </xsl:template>
       <!-- Object Properties -->
       <xsl:template name="Properties">
              <xsl:variable name="childName" select="name(*[1])"/>
              <xsl:choose>
                     <xsl:when test="not(*|@*)">"<xsl:value-of select="."/>"</xsl:when>
                     <xsl:when test="count(*[name()=$childName]) > 1">{ "<xsl:value-of select="$childName"/>" :[<xsl:apply-templates select="*" mode="ArrayElement"/>] }</xsl:when>
                     <xsl:otherwise>{
                <xsl:apply-templates select="@*"/>
                           <xsl:apply-templates select="*"/>
    }</xsl:otherwise>
              </xsl:choose>
              <xsl:if test="following-sibling::*">,</xsl:if>
       </xsl:template>
       <!-- Attribute Property -->
       <xsl:template match="@*">"<xsl:value-of select="name()"/>" : "<xsl:value-of select="."/>",
    </xsl:template>

Вот что я сейчас делаю:

{

        "ns1:DDMRP_Parts" : { "Part" :[{

        "PartNumber" : "000096",
        "Location" : "A000",
        "Description" : "TEST OF RAMIS",
        "UnitOfMeasure" : "EA",
        "PartType" : "1",
        "FixedLeadTime" : "1",
        "MaterialType" : "Filling & Mixing Eq"
    },{

        "PartNumber" : "000096",
        "Location" : "A000",
        "Description" : "TEST OF RAMIS",
        "UnitOfMeasure" : "EA",
        "PartType" : "1",
        "FixedLeadTime" : "1",
        "MaterialType" : "Filling & Mixing Eq"
    }] }}

Вот что мне нужно вывести:

[{

        "PartNumber" : "000096",
        "Location" : "A000",
        "Description" : "TEST OF RAMIS",
        "UnitOfMeasure" : "EA",
        "PartType" : "1",
        "FixedLeadTime" : "1",
        "MaterialType" : "Filling & Mixing Eq"
    },{

        "PartNumber" : "000096",
        "Location" : "A000",
        "Description" : "TEST OF RAMIS",
        "UnitOfMeasure" : "EA",
        "PartType" : "1",
        "FixedLeadTime" : "1",
        "MaterialType" : "Filling & Mixing Eq"
    }]

Answer 1

Я предлагаю вам попробовать это следующим образом:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:template match="/*">
    <!-- array -->
    <xsl:text>[&#10;</xsl:text>
    <xsl:apply-templates select="*"/>
    <xsl:text>&#10;]</xsl:text>
</xsl:template>

<xsl:template match="*">
    <!-- object -->
    <xsl:text>&#9;{&#10;</xsl:text>
    <xsl:apply-templates select="*" mode="data"/>
    <xsl:text>&#10;&#9;}</xsl:text>
    <xsl:if test="position()!=last()">
        <xsl:text>,&#10;</xsl:text>
    </xsl:if>
</xsl:template>

<xsl:template match="*" mode="data">
    <!--  name/value pair -->
    <xsl:text>&#9;&#9;"</xsl:text>
    <xsl:value-of select="name()"/>
    <xsl:text>" : "</xsl:text>
    <xsl:value-of select="."/>
    <xsl:text>"</xsl:text>
    <xsl:if test="position()!=last()">
        <xsl:text>,&#10;</xsl:text>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

---

PS Пробельные символы являются необязательными и могут быть удалены, не затрагиваядостоверность результата JSON.