Ошибка отладки при снятии защиты с книги, открытой в новом окне

Question

У меня есть рабочая книга, которая импортирует данные из рабочих книг, созданных с веб-сайтов.Когда веб-сайты создают рабочие книги, они автоматически открываются в новом окне, и имена рабочих книг всегда меняются.Я использую

ActiveWindow.ActivateNext

Одна из рабочих книг должна быть открыта в защищенном виде, поэтому я использую

Application.ActiveProtectedViewWindow.Edit

, чтобы разрешить ее редактирование перед импортом

Я могупошагово просматривайте макрос, и он работает, но когда я запускаю его, я всегда получаю «Ошибка времени выполнения 91»: переменная объекта или переменная блока не установлена. Я нажимаю «Отладка и воспроизведение», и программа завершает работу без проблемы.

Полный код выглядит так:

Sub Data()
Dim Here As String
Dim What As String
Dim Data As String
Dim DropIt As String
Dim StartBook As String

Application.DisplayAlerts = False

StartBook = ActiveWorkbook.Name

DropIt = "Data1"
ActiveWindow.ActivateNext
Application.ActiveProtectedViewWindow.Edit 'THIS IS WHERE THE DEBUG HAPPENS

Range("A1").Select
Here = ActiveSheet.Name
BookName = ActiveWorkbook.Name

    Rows("1:3").Select
    Selection.Delete Shift:=xlUp
    Rows("2:2").Select
    Selection.Delete Shift:=xlUp
    Columns("E:E").Select
    Selection.Delete Shift:=xlToLeft
    Columns("C:C").Select
    Selection.Delete Shift:=xlToLeft
    Columns("A:A").Select
    Selection.Delete Shift:=xlToLeft
Range("A1").Select
What = Range("A1", ActiveCell.SpecialCells(xlLastCell)).Address
Data = Range("A2", ActiveCell.SpecialCells(xlLastCell)).Address

    ActiveWorkbook.Worksheets(Here).Sort.SortFields.Clear
    ActiveWorkbook.Worksheets(Here).Sort.SortFields.Add2 Key:=Range("A1") _
        , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With ActiveWorkbook.Worksheets(Here).Sort
        .SetRange Range(What)
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With

    Range(Data).Copy

    Workbooks(StartBook).Activate
    Worksheets(DropIt).Select
    Range("a10").Select
    ActiveCell.End(xlDown).Select

    Range(Selection, ActiveCell.End(xlToRight)).Select

    ActiveCell.Offset(1, 0).Select

    ActiveCell.PasteSpecial xlPasteValues
        Application.CutCopyMode = False        

    Application.DisplayAlerts = False

        Workbooks(BookName).Close savechanges:=False
Application.DisplayAlerts = True
End Sub

Я просто хочу, чтобы код работал без отладки

'' ''

Answer 1

Я не могу проверить, но я сделаю непроверенное предложение. Попробуйте изменить:

ActiveWindow.ActivateNext
Application.ActiveProtectedViewWindow.Edit

до:

Dim someWorkbook as Workbook
Set someWorkbook = Application.ProtectedViewWindows(1).Edit

Я думаю, что есть другие потенциальные проблемы с вашим кодом.

---

Ошибки, которые «исчезают» при отладке / пошаговом выполнении кода, обычно указывают на то, что ваш код ожидал, что что-то будет активным во время выполнения, но он (по какой-либо причине) не был активным (отсюда и ошибка) - и теперь что вы шаг за шагом проходите через него, объект активен, и вы больше не получаете сообщение об ошибке. Это не всегда так, но я думаю, что это возможно.

Я не знаком с ActiveProtectedViewWindow, но я бы посоветовал вам вместо этого обратиться к ProtectedViewWindow более надежным способом (который не зависит от активности ProtectedViewWindow).

Если вы уверены, что будет только 1 защищенное окно, вы можете попробовать что-то вроде Application.ProtectedViewWindows(1).Edit. Если у вас есть несколько ProtectedViewWindows, и вам нужен только конкретный, возможно, вы можете перебрать все ProtectedViewWindows и проверить, соответствует ли их свойство SourcePath пути защищенной книги, в которой вы хотите разрешить редактирование.

Из того, что я прочитал в Интернете, ProtectedViewWindow.Edit возвращает рабочую книгу, поэтому вы можете тут же установить ссылку на нее Workbook (как показано в начале моего ответа).

Я не проверял нижеприведенное, но я думаю, что ваш код может быть переписан примерно так. Я рекомендую сохранить копии рабочих книг / файлов перед запуском (или пройти по нему с помощью клавиши F8):

Option Explicit

Sub Data()
    Dim startWorkbook As Workbook ' Do you have better name for this variable?
    Set startWorkbook = ActiveWorkbook ' Can you refer to this workbook by name, instead of assuming it will be active? Using ThisWorkbook is an option too, as long as you're storing the code in startWorkbook

    Dim unprotectedWorkbook As Workbook ' This needs a better variable name.
    Set unprotectedWorkbook = Application.ProtectedViewWindows(1).Edit ' I don't know if this will work for you (in your case), but I've taken it from Microsoft's documentation

    Dim someWorksheet As Worksheet
    someWorksheet = unprotectedWorkbook.Worksheets(1) ' If you know the worksheet's name, refer to it by name, please.

    With someWorksheet
        .Rows("1:3").Delete Shift:=xlUp
        .Rows("2:2").Delete Shift:=xlUp
        .Columns("E:E").Delete Shift:=xlToLeft
        .Columns("C:C").Delete Shift:=xlToLeft
        .Columns("A:A").Delete Shift:=xlToLeft

        ' xlCellTypeLastCell isn't always the best way to get the last cell.
        Dim someRangeIncludingHeaders As Range ' This needs a better name.
        Set someRangeIncludingHeaders = .Range("A1", .Cells.SpecialCells(xlCellTypeLastCell))

        Dim someRange As Range ' This needs a better name.
        Set someRange = .Range("A2", .Cells.SpecialCells(xlCellTypeLastCell))

        With .Sort
            .SortFields.Clear
            .Sort.SortFields.Add2 Key:=.Range("A1"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
            .SetRange someRangeIncludingHeaders
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    End With

    someRange.Copy
    startWorkbook.Worksheets("Data1").Range("A10").PasteSpecial xlPasteValues
    Application.CutCopyMode = False

    unprotectedWorkbook.Close SaveChanges:=False
End Sub

Основные изменения, которые я сделал:

• ActiveSheet не используется, поэтому код должен выполняться одинаково (независимо от того, какой лист оказался активным).
• Ссылками на объекты являются set для рабочих книг, рабочих таблиц, диапазонов.
• Вместо использования Select или Selection мы ссылаемся на диапазон по его адресу в явном виде.
• Блок операторов With в основном для удобства. Каждый объект, который начинается с . внутри блока With, является членом объекта после ключевого слова With (в данном случае someWorksheet).