Перебрать файл XML и выбрать только определенные узлы

Question

У меня есть следующий файл JSON, который я хотел бы преобразовать через XSLT.

[
    {
    "firstName": "John",
    "lastName": "Andy",
    "age": "15"
    },
    {
    "firstName": "Ann",
    "lastName": "Heather",
    "age": "13"
    }

] 

и имеют следующий результат:

[
    {
    "firstName": "John",
    "lastName": "Andy"
    },
    {
    "firstName": "Ann",
    "lastName": "Heather"
    }

]

Что я делаю, это преобразовываю JSON в XML и затем манипулирую файлом, используя следующий код:

<xsl:param name="json" as="xs:string">
     <xsl:template match="/*" name="xsl:initial-template">
            <xsl:variable name="input-as-xml"  select="json-to-xml($json)"/>     
            <xsl:variable name="transformed-xml" as="element(array)">
                <array xmlns="http://www.w3.org/2005/xpath-functions">
                    <xsl:for-each select="/node()">
                        <map xmlns="http://www.w3.org/2005/xpath-functions">
                            <string key="firstName">
                                <xsl:value-of select="$input-as-xml//string[@key='firstName']"/>
                            </string>
                            <string key="lastName">
                                <xsl:value-of select="$input-as-xml//string[@key='lastName']"/>
                            </string>
                        </map>
                    </xsl:for-each>
                </array>
            </xsl:variable>
            <xsl:value-of select="xml-to-json($transformed-xml)"/>
        </xsl:template>

Мой вывод с использованием приведенного выше кода:

[
    {
        "firstName": "John Ann John Ann",
        "lastName": "Andy Heather Andy Heather"
    }
]

Мне понадобится некоторая помощь, чтобы изменить свой код, чтобы получить необходимую информацию в ожидаемом порядке.

Answer 1

Я бы настоятельно рекомендовал придерживаться подхода, предложенного в ответе на ваш предыдущий вопрос, то есть проталкивать результат json-to-xml через шаблоны, поэтому для удаления age вам просто нужен пустой шаблон:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xpath-default-namespace="http://www.w3.org/2005/xpath-functions"
    xmlns="http://www.w3.org/2005/xpath-functions"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:param name="json" as="xs:string">
[
    {
    "firstName": "John",
    "lastName": "Andy",
    "age": "15"
    },
    {
    "firstName": "Ann",
    "lastName": "Heather",
    "age": "13"
    }

]  
  </xsl:param>

  <xsl:output method="text"/>

  <xsl:template match="/" name="xsl:initial-template">
      <xsl:variable name="transformed-json-xml">
            <xsl:apply-templates select="json-to-xml($json)/node()"/>
      </xsl:variable>
      <xsl:value-of select="xml-to-json($transformed-json-xml, map { 'indent' : true() })"/>
  </xsl:template>

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="string[@key = 'age']"/>

</xsl:stylesheet>

https://xsltfiddle.liberty -development.net / bnnZWD / 11

Answer 2

Ваш xsl:for-each неправильно устанавливает контекст. Я думаю, что вы, вероятно, хотите:

    <xsl:for-each select="$input-as-xml/*/*">
        <map xmlns="http://www.w3.org/2005/xpath-functions">
           <string key="firstName">
              <xsl:value-of select="string[@key='firstName']"/>
           </string>
           <string key="lastName">
              <xsl:value-of select="string[@key='lastName']"/>
          </string>
        </map>
   </xsl:for-each>

Но я думаю, что вы можете упростить это, используя xsl: copy-of:

    <xsl:for-each select="$input-as-xml/*/*">
        <map xmlns="http://www.w3.org/2005/xpath-functions">
           <xsl:copy-of select="*[@key=('firstName', 'lastName')]"/>
        </map>
   </xsl:for-each>