Проблема свертки в том, что KeyPressed разные изображения, например, Sharpen - PullRequest
Новая
       9

Проблема свертки в том, что KeyPressed разные изображения, например, Sharpen

1 голос
/ 15 апреля 2019

Отображение разных изображений с разными видами. Например, резкость одна. Я не могу заставить его показать Sharpen. Я не могу узнать, как закончить точить. Я использовал код профессора в качестве примера.

Есть и другие: 

blur 3 x 3 
blur 5 x 5
edge detection
grayscale 
RGB > GRB
Zoom in
Zoom out

Я попытался добавить 1 в цикл for вместо нуля.

Вот код: 

PImage source;
PImage destination;
int w = 80;
float[][] matrix_3_3_average = { 
    {1.0/9.0, 1.0/9.0, 1.0/9.0 }, 
    {1.0/9.0, 1.0/9.0, 1.0/9.0 }, 
    {1.0/9.0, 1.0/9.0, 1.0/9.0 }
};
float[][] matrix_3_3_sharpen = 
    { { -1, -1, -1 }, 
    { -1, 9, -1 }, 
    { -1, -1, -1 } };

void setup() {

    size(200, 200);
    source = loadImage("sunflower.jpg");          
    destination = createImage(source.width, source.height, RGB);
}

void draw() {
    destination.loadPixels(); // Tell Processing that we want to read the pixels of the output window
    source.loadPixels(); 
    int xStart = constrain(mouseX - w/2, 0, width);
    int xEnd = constrain(mouseX + w/2, 0, width);
    int yStart = constrain(mouseY - w/2, 0, height);
    int yEnd = constrain(mouseY + w/2, 0, height);

    if (keyPressed) {
        if (key == '0') {
            image(source, 0, 0);
            for (int x = 1; x < source.width; x++) {
                for (int y = 1; y < source.height; y++) {
                    int loc = x + y * source.width;

                    if ((x > xStart) && (x < xEnd) && (y > yStart) && (y < yEnd)) 
                        destination.pixels[loc] = convolution(x, y, matrix_3_3_average, 3, source);
                    else 
                        // set the color of the corresponding pixel to the output window to the color of the pixel to the input image
                        destination.pixels[loc] = source.pixels[loc];
                }
            }
        } else if (key == '1') {
            for (int x = 1; x < source.width; x++) {
                for (int y = 1; y < source.height; y++) {
                    int loc = x * y * source.width;
                    if ((x > xStart) && (x <xEnd) && (y > yStart) && (y < yEnd))
                        destination.pixels[loc] = convolution(x, y, matrix_3_3_sharpen, 3, source);
                    else
                        destination.pixels[loc] = source.pixels[loc];
                }
            }
        }
    }
}    

color convolution(int x, int y, float[][] matrix, int matrixSize, PImage img) {
    int offset = (matrixSize - 1)/2;
    float r = 0;
    float g = 0;
    float b = 0;
    for (int i = 0; i < matrixSize; i++) {  
        for (int j = 0; j < matrixSize; j++) {
            int xLoc = x + i - offset;
            int yLoc =  y + j - offset;
            int loc = xLoc * yLoc * img.width;

            loc = constrain(loc, 0, img.pixels.length-1);

            r = r + matrix[i][j] * red(img.pixels[loc]);
            g = g + matrix[i][j] * green(img.pixels[loc]);
            b = b + matrix[i][j] * blue(img.pixels[loc]);
        }
    }
    return color(r, g, b);
}

1 Ответ

0 голосов
/ 15 апреля 2019

Существует проблема, когда индекс пикселя в плане изображения вычисляется в функции convolution. Индекс пикселя составляет x + y * width, а не x * width:

int loc = xLoc * yLoc * img.width;</s> int loc = xLoc + yLoc * img.width;

Скопируйте изображение source в destination при запуске и непрерывно рисуйте изображение destination: 

void setup() {

    size(200, 200);
    source = loadImage("C:/temp/flower.jpg"); //source = loadImage("sunflower.jpg"); 
    destination = createImage(source.width, source.height, RGB);
    destination.copy(source, 0, 0, source.width, source.height, 0, 0, source.width, source.height);
}

void draw() {

    // [...]

    image(destination, 0, 0);
}

Используйте событие keyPressed(), чтобы определить, была ли нажата кнопка key, которая начинается с фильтра изображения: 

boolean average = key == '0';
boolean sharpen = key == '1';

void keyPressed() {
    average = key == '0';
    sharpen = key == '1';
}

Когда выполняется фильтр изображений, копируйте копию source изображения в destination изображение. Обновите пиксель в отфильтрованной области. Наконец, скопируйте измененное изображение destination в исходное изображение, чтобы подготовиться к следующей операции фильтрации: 

destination.copy(source, 0, 0, source.width, source.height, 0, 0, source.width, source.height);
for (int x = 0; x < source.width; x++) {
    for (int y = 0; y < source.height; y++) {
        int loc = x + y * source.width;

        if (x > xStart && x < xEnd && y > yStart && y < yEnd) {
            if ( average )
                destination.pixels[loc] = convolution(x, y, matrix_3_3_average, 3, source);
            else
                destination.pixels[loc] = convolution(x, y, matrix_3_3_sharpen, 3, source);
        }
    }
}

source.copy(destination, 0, 0, source.width, source.height, 0, 0, source.width, source.height);

См. Пример, где я применил предложения к коду вашего вопроса: 

PImage source;
PImage destination;
int w = 80;
float[][] matrix_3_3_average = { 
    {1.0/9.0, 1.0/9.0, 1.0/9.0 }, 
    {1.0/9.0, 1.0/9.0, 1.0/9.0 }, 
    {1.0/9.0, 1.0/9.0, 1.0/9.0 }
};
float[][] matrix_3_3_sharpen = 
    { { -1, -1, -1 }, 
    { -1, 9, -1 }, 
    { -1, -1, -1 } };

void setup() {

    size(200, 200);
    source = loadImage("C:/temp/flower.jpg"); //source = loadImage("sunflower.jpg"); 
    destination = createImage(source.width, source.height, RGB);
    destination.copy(source, 0, 0, source.width, source.height, 0, 0, source.width, source.height);
}

boolean average = key == '0';
boolean sharpen = key == '1'; 

void keyPressed() {
    average = key == '0';
    sharpen = key == '1'; 
}

void draw() {

    int xStart = constrain(mouseX - w/2, 0, width);
    int xEnd = constrain(mouseX + w/2, 0, width);
    int yStart = constrain(mouseY - w/2, 0, height);
    int yEnd = constrain(mouseY + w/2, 0, height);
    println(xStart, xEnd, yStart, yEnd);

    if (average || sharpen) { 

        destination.copy(source, 0, 0, source.width, source.height, 0, 0, source.width, source.height);
        for (int x = 0; x < source.width; x++) {
            for (int y = 0; y < source.height; y++) {
                int loc = x + y * source.width;

                if (x > xStart && x < xEnd && y > yStart && y < yEnd) {
                    if ( average )
                        destination.pixels[loc] = convolution(x, y, matrix_3_3_average, 3, source);
                    else
                        destination.pixels[loc] = convolution(x, y, matrix_3_3_sharpen, 3, source);
                }                   
            }
        }

        source.copy(destination, 0, 0, source.width, source.height, 0, 0, source.width, source.height);
        average = sharpen = false; 
    }

    image(destination, 0, 0);
}  

color convolution(int x, int y, float[][] matrix, int matrixSize, PImage img) {
    int offset = (matrixSize - 1)/2;
    float r = 0;
    float g = 0;
    float b = 0;
    for (int i = 0; i < matrixSize; i++) {  
        for (int j = 0; j < matrixSize; j++) {
            int xLoc = x + i - offset;
            int yLoc = y + j - offset;
            int loc = xLoc + yLoc * img.width;

            loc = constrain(loc, 0, img.pixels.length-1);

            r = r + matrix[i][j] * red(img.pixels[loc]);
            g = g + matrix[i][j] * green(img.pixels[loc]);
            b = b + matrix[i][j] * blue(img.pixels[loc]);
        }
    }
    return color(r, g, b);
}
...