Applescript, чтобы открыть YouTube в приватном режиме сафари

Question

Как открыть YouTube в приватном режиме Safari?

Я пробовал это, но оно не работает:

tell application "Safari" to activate
tell application "System Events"
tell process "Safari"
      click menu item "New Private Window" of menu "File" of menu bar 1
      open location "https://www.youtube.com"  -- this will open default browser
end tell
end tell

Мой браузер по умолчанию - Chrome, и он открывает YouTubeв chrome не в приватном режиме сафари.

Как это исправить?

Answer 1

У меня действительно нет лучшего решения для Safari, чем то, которое предлагает @ user3439894.Единственное, что я бы сделал по-другому, - это создаю новое частное окно, используя этот код (который, вероятно, равен «6 из 1 или 1/2 десятка другого»)

tell application "Safari" to activate
tell application "System Events" to tell its application process "Safari"
    set frontmost to true
    keystroke "n" using {shift down, command down}
end tell

Однако выможет предпочесть это решение для Google Chrome, поскольку оно не требует использования системных событий и не требует, чтобы Google Chrome был активным или самым активным.

tell application "Google Chrome"
    set incognitoWindow to (make new window with properties {mode:"incognito"})
    repeat while loading of active tab of incognitoWindow
        delay 0.1
    end repeat
    set URL of active tab of incognitoWindow to "http://youtube.com"
end tell

Answer 2

Следующий пример AppleScript код работает для меня:

Для Safari Использование:

activate application "Safari"

tell application "System Events" to ¬
    click menu item "New Private Window" of ¬
        menu "File" of menu bar 1 of ¬
        application process "Safari"

tell application "Safari" to ¬
    set URL of current tab of ¬
        front window to "https://www.youtube.com"

_{Примечание. При желании каждый из двух операторов tell может быть расположен на отдельной строке, удалив символ ¬ , продолжение строки и невидимый символ перевода строки , следующий за ним.}

Для Google Chrome используйте:

activate application "Google Chrome"

tell application "System Events" to ¬
    click menu item "New Incognito Window" of ¬
        menu "File" of menu bar 1 of ¬
        application process "Google Chrome"

tell application "Google Chrome" to ¬
    set URL of active tab of ¬
        front window to "https://www.youtube.com"

_{Примечание. При желании каждый из двух операторов tell может располагаться на отдельной строке, удаляя символ ¬ , продолжение строки и невидимый перевод строки , следующий за ним.}

---

Примечание. Пример AppleScript code является только этим и не содержит обработки ошибок, которая может быть уместной. Пользователь должен добавить любую обработку ошибок, которая может быть уместной, необходимой или требуемой. Взгляните на оператор try и error оператор в Руководство по языку AppleScript . См. Также Работа с ошибками .