«Ошибка времени выполнения 1004» с кодом VBA инициировала экспорт PDF

Question

Я пытаюсь экспортировать лист в PDF, но когда я запускаю код, я получаю сообщение об ошибке 1004.

Я полагаю, что это связано с путем к папке, к месту сохранения. Я пытался определить путь к файлу по-разному, но все равно получаю ошибку.

Предполагается, что этот код извлекает часть имени файла из ячейки B1 и путь к файлу из расположения листа. Предполагается, что файл PDF будет сохранен в месте нахождения листа. Я довольно новичок в VBA. Любая помощь приветствуется!

Вот код

Sub ExportAsPDFTest()

Dim Name As String
Dim Preface As String


Name = Cells(1, "B").Value
Preface = "PreR Summer 2019 - "

ActiveSheet.ExportAsFixedFormat _
    Type:=xlTypePDF, _
    FileName:=ActiveWorkbook.Path & Preface & Name & ".pdf", _
    Quality:=xlQualityStandard, _
    IncludeDocProperties:=False, _
    IgnorePrintAreas:=False, _
    From:=1, _
    To:=1, _
    OpenAfterPublish:=False

End Sub

Answer 1

Вам не хватает обратной косой черты \ (или /, если вы на Mac) после ActiveWorkbook.Path.Вы можете использовать Application.PathSeparator, поэтому он будет работать на обоих:

Sub ExportAsPDFTest()
    Dim Name As String
    Dim Preface As String

    Name = Cells(1, "B").Value
    Preface = "PreR Summer 2019 - "

    ActiveSheet.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=ActiveWorkbook.Path & Application.PathSeparator & Preface & Name & ".pdf", _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=False, _
        IgnorePrintAreas:=False, _
        From:=1, _
        To:=1, _
        OpenAfterPublish:=False
End Sub

Надеюсь, это поможет.

Answer 2

Пожалуйста, добавьте msgbox Activeworkbook.path, чтобы проверить путь сохранения, вам нужно добавить еще один "\"