Как изменить Finder на родительский каталог в AppleScript?

Question

Мне нужно создать Mac Automator или AppleScript, чтобы выполнить следующие действия: 1) Выбрать группу файлов 2) Переименовать расширение выбранных файлов 3) Переместить переименованные файлы в родительскую папку родительской папки (на 2 уровня выше).) Я могу сделать 1 и 2 в Automator, но я предполагаю, что мне нужен скрипт для # 3.Любая помощь будет оценена!

Answer 1

tell application "Finder"
    set OriginalSin to the insertion location
    set Man to a reference to the parent of OriginalSin
    set Lord to a reference to the parent of Man

    if not (the Lord exists) then return "Dawkins was right."

    set the Shadows to make new folder at OriginalSin ¬
        with properties {name:"___EVIL___"}

    move the selection to the Shadows

    set Worthy to a reference to every file in the Shadows
    set the name extension of the Worthy to "god"


    set Forsaken to the name in the Lord's files
    set Righteous to the Worthy where its name is not in the Forsaken

    move the Righteous to the Lord without replacing
    move the Worthy to OriginalSin
    delete the Shadows
end tell

Я бы не использовал «бог» в качестве имени расширения, он не распознается системой как известный тип файла.На самом деле, рассмотрим , почему вы хотите изменить расширение файла вручную, что, помимо простого текстового файла, я не могу вспомнить в ситуации ^† , где это было бы необходимо.macOS использует расширения файлов, чтобы помочь определить тип файла и связать их с соответствующими приложениями, которые больше не смогут выполнять функции открывателей для файлов, которые вы изменяете.

^{† На самом деле, "e" в ".jpeg" действительно заслуживает смерти}

Answer 2

Этот код AppleScript работает для меня, используя последнюю версию macOS Mojave.

Этот следующий код должен делать все, что вам нужно.

property setNameExtension : "jpg" -- Change To Whatever You Want

tell application "Finder"
    set selectedFiles to selection as alias list -- Currently Selected Files In Finder
    set containerOfContainerOf to container of (container of item 1 of selectedFiles)
    repeat with i in selectedFiles
        set renamedItems to move i to containerOfContainerOf
        set the name extension of renamedItems to setNameExtension
    end repeat
end tell

Answer 3

это должно помочь вам начать

tell application "Finder" to get (container of (path to me)) as text

где путь ко мне может быть любым путем HFS (например, путь к одному из ваших файлов)