Oracle - «Выражение неправильного типа» Возвращает таблицу типа записи в пакете - PullRequest
Новая
       19

Oracle - «Выражение неправильного типа» Возвращает таблицу типа записи в пакете

1 голос
/ 28 апреля 2019

При попытке проверить функцию, определенную в пакете, который возвращает таблицу с типом записи, я получаю «выражение неправильного типа».
Вот заголовок: 

create or replace package pck_prestamos is
type r_cuotas is record
    (saldo_capital number(12),
    amortizacion number(12),
    interes number(12),
    seguro_vida number(8),
    monto_cuota number(15),
    fecha_vencimiento date);
type t_cuotas is table of r_cuotas
    index by binary_integer;
--v_cuotas t_cuotas;
function f_calcular_cuotas(monto_p number,t_i_a number, plazo_p number, fecha_d date) return t_cuotas;
end;
/

А вот и тело: 

create or replace package body pck_prestamos is
function f_calcular_cuotas(monto_p number,t_i_a number, plazo_p number, fecha_d date) return t_cuotas is
    saldo_capital_ant number;
    amortizacion_capital_ant number;
    diferencia number;
    porc_seg_v gen_parametros.porc_seg_vida%type;
    v_cuotasf t_cuotas;
begin
    select porc_seg_vida into porc_seg_v
        from gen_parametros;
    for i in 1..plazo_p loop
        if i = 1 then 
            v_cuotasf(i).saldo_capital := monto_p;
            saldo_capital_ant := v_cuotasf(i).saldo_capital;
            amortizacion_capital_ant := monto_p/plazo_p;
        else
            v_cuotasf(i).saldo_capital := saldo_capital_ant - amortizacion_capital_ant;
            saldo_capital_ant := v_cuotasf(i).saldo_capital;
        end if;
        if i = plazo_p then
            diferencia := v_cuotasf(i).saldo_capital - amortizacion_capital_ant;
            v_cuotasf(i).amortizacion := (monto_p/plazo_p) + diferencia;
        else 
            v_cuotasf(i).amortizacion := monto_p/plazo_p;
        end if;
        v_cuotasf(i).interes := ((t_i_a/12)/100)*v_cuotasf(i).saldo_capital;
        v_cuotasf(i).seguro_vida := (porc_seg_v/100)*v_cuotasf(i).saldo_capital;
        v_cuotasf(i).monto_cuota := v_cuotasf(i).amortizacion + v_cuotasf(i).interes + v_cuotasf(i).seguro_vida;
        v_cuotasf(i).fecha_vencimiento := fecha_d + 30*i; 
    end loop;
    return v_cuotasf;
end;
end;
/

Вот как я пытаюсь это проверить: 

declare
type r_cuotas is record
    (saldo_capital number(12),
    amortizacion number(12),
    interes number(12),
    seguro_vida number(8),
    monto_cuota number(15),
    fecha_vencimiento date);
type t_cuotas is table of r_cuotas
    index by binary_integer;
v_cuotas t_cuotas;
begin
v_cuotas := pck_prestamos.f_calcular_cuotas(10000000,10,18,sysdate);
end;
/

Обе части пакета компилируются без проблем.
Полная ошибка: 

ERROR at line 13:  
ORA-06550: line 13, column 13:  
PLS-00382: expression is of wrong type  
ORA-06550: line 13, column 1:  
PL/SQL: Statement ignored

Я что-то упустил? Спасибо.

1 Ответ

4 голосов
/ 28 апреля 2019

С точки зрения Oracle, t_cuotas, объявленный в вашем тестовом блоке, отличается от типа, объявленного в вашем пакете, даже если они могут иметь одинаковые элементы и «выглядеть» одинаково для вас и для меня. Вам необходимо использовать t_cuotas, определенный в вашем пакете, указав его в имени пакета: 

declare
  v_cuotas pck_prestamos.t_cuotas;
begin
  v_cuotas := pck_prestamos.f_calcular_cuotas(10000000,10,18,sysdate);
end;
/

Дай попробовать.

...