как работает vlook up, когда у нас есть дубликаты в первом столбце таблицы

Question

есть 2 разных файла, которые я хотел проверить на основе vehicle_ID (посмотрите значение), есть ли изменение цвета между двумя файлами.но здесь дублируется в столбце идентификатора транспортного средства, поэтому я не получаю точное значение

VIN                  MAPPED_COLOR

VF12R071659666728   Cappuccino Noir Etoilé       
VF12R071659666728   Gris Cassiopée Noir Étoil
VF12R071659666730   Gris Platine Noir Etoilé
VF12R071659666731   Noir Etoilé Ivoire
VF12R071659666752   Rouge Flamme Noir Etoilé

---

=VLOOKUP($C$2:$C$25576,'[IZMOVN - COLOR MATCHING REPORT_3rd_July_2019_1.xlsx]IZMOVN - COLOR MATCHING REPORT'!$A:$Z,15,0)

---

VIN                     MAPPED_COLOR            V_loop_up_MAPPED_COLOR

VF12R071659666728   Cappuccino Noir Etoilé      Cappuccino Noir Etoilé  
VF12R071659666728   Gris Cassiopée Noir Étoil   Cappuccino Noir Etoilé  
VF12R071659666730   Gris Platine Noir Etoilé    Gris Platine Noir Etoilé    
VF12R071659666731   Noir Etoilé Ivoire          Noir Etoilé Ivoire  TRUE
VF12R071659666752   Rouge Flamme Noir Etoilé    Rouge Flamme Noir Etoilé    

Answer 1

Если ваша таблица данных data1 выглядит следующим образом, добавьте вспомогательный столбец перед столбцом MAPPED_COLOR, как показано на рисунке (1) ниже, используя формулу

=A2 & "-" & COUNTIF($A$1:A2,A2)

, чтобы добавить число вхождений -1, -2 в VIN, чтобы сделать их уникальными для вашего поиска.

^{Изображение 1: Лист «Данные1»}

Затем на другом листе добавьте столбцы от 1 до 4 или более. Обратите внимание, что имена должны быть числами (больше ничего!). Тогда воспользуйтесь следующим форумом в B2

=IF(COUNTIF(Data1!$A:$A,$A2)>=B$1,VLOOKUP($A2 & "-" & B$1,Data1!$B:$C,2,FALSE),"")

и скопируйте его вправо и вниз, чтобы получить результат ниже:

^{Изображение 2: Лист «Данные2» ​​}

Answer 2

При условии, что у вас будет только два совпадения для номера VIN (из двух источников данных), вы можете использовать эту формулу, чтобы найти второе совпадение: =INDEX(B1:B6,SMALL(IF(A1:A6=D2,ROW(A1:A6)-MIN(ROW(A1:A6))+1),2))

(Обратите внимание, что это формула массива, и ее необходимо закрыть с помощью CTRL +, SHIFT + ENTER вместо ENTER )

Формулы, которые я использовал на скриншоте ниже:

E2: =INDEX(B1:B6,MATCH(D2,A1:A6,0))

F2: =INDEX(B1:B6,SMALL(IF(A1:A6=D2,ROW(A1:A6)-MIN(ROW(A1:A6))+1),2)) ( CTRL +, SHIFT + ENTER )

G2: =IF(COUNTIFS(A1:A7,D2)>1,INDEX($B$1:$B$7,SMALL(IF($A$1:$A$7=$D2,ROW($A$1:$A$7)-MIN(ROW($A$1:$A$7))+1),2))=INDEX($B$1:$B$7,MATCH($D2,$A$1:$A$7,0)),TRUE) ( CTRL +, SHIFT + ENTER )