Моя гистограмма gnuplot не нормирована на 1, а на какое-то другое значение.Зачем?

Question

Я построил гистограмму, используя gnuplot, но она как-то не нормализуется до 1, а к другому значению.

Код gnuplot, который я использую:

n=50
min=0.82166501
max=1.66893753
width=(max-min)/50 
hist(x,width)=width*floor(x/width)
plot 'CHbl.dat' u (hist($1,width)):(1.0/(2880144*width)) smooth freq w lines lc rgb"red" title "CH"

Здесь,2880144 - это мое количество точек данных.Гистограмма, которую я получаю в качестве вывода:

Почему это происходит?Как мне нормализовать его до 1?

Answer 1

Существует несколько способов масштабирования гистограммы. Давайте возьмем некоторые случайные данные. Вы можете поместить данные в x-bin и

a) суммирует все значения y в ячейке. Это ... :2 smooth frequency

b) суммируйте все значения y в ячейке и масштабируйте их так, чтобы область была 1. Это ... :2 smooth fnormal

c) подсчитать случаи в корзине. Это ... :(1) smooth frequency

d) Суммируйте все значения y в ячейке и нормализуйте их по пику. Это ...:($2/STATS_max)

Как говорит Итан, нормализация обычно происходит в область = 1, то есть б). Вы спрашиваете о г)?

Код:

### Normalized histograms
reset session
set key top left

set samples 10000
set table $Data
    plot [-5:5][-5:5]'+' u (invnorm(rand(0))):(rand(0)) w table
unset table

min = -5
max = 5
width = (max-min)/50.
bin(x) = width*floor(x/width)

set multiplot layout 2,2
    plot $Data u (bin($1)):2 smooth frequency w boxes lc rgb "red" title "smooth frequency"
    plot $Data u (bin($1)):2 smooth fnormal w boxes lc rgb "web-green" t "smooth fnormal"
    plot $Data u (bin($1)):(1) smooth frequency w boxes lc rgb "web-blue" t "occurrences per bin"

    set table $FindMax
        plot $Data u (bin($1)):2 smooth frequency
    unset table
    stats $FindMax u 2 nooutput
    plot $Data u (bin($1)):($2/STATS_max) smooth frequency w boxes lc rgb "magenta" t "normalized max to 1"
unset multiplot
### end of code

Результат: