Создайте файл базы данных MS Access с паролем из Excel VBA

Question

Я хочу создать файл MS Access .mdb в Excel VBA. Я хочу установить пароль для этого файла Access в Excel VBA.

Этот код ниже может создать файл доступа, но без пароля.

Sub Example1()
    'the path to create the new access database
    Dim strPath As String
    'an Access object
    Dim objAccess As Object

    strPath = "D:\VBA\NewDB2.mdb"
    Set objAccess = CreateObject("Access.Application")
    Call objAccess.NewCurrentDatabase(strPath)
    objAccess.Quit
End Sub

Как мне установить пароль?

Answer 1

Обратите внимание: если вы используете Office 2007 или новее, вы должны добавить параметр FileFormat, чтобы файл Access имел формат mdb:

'create new database
objAccess.NewCurrentDatabase strPath, 10

10, являясь значениемacNewDatabaseFormatAccess2002 константа .

Answer 2

Должно быть что-то вроде этого

Option Explicit

Public Sub CreatePasswordProtectedDatabase()
    Dim strPath As String
    strPath = "D:\VBA\NewDB2.mdb"

    'create new Access application
    Dim objAccess As Object
    Set objAccess = CreateObject("Access.Application")

    'objAccess.Visible = True 'show or hide Access

    'create new database
    objAccess.NewCurrentDatabase strPath

    'example to add a table
    objAccess.DoCmd.RunSQL "CREATE TABLE Test", False
    objAccess.DoCmd.RunSQL "ALTER TABLE Test add Gender char(1)", False

    'set password
    Dim DbPassword As String
    DbPassword = "your_password"
    objAccess.CurrentProject.Connection.Execute "ALTER DATABASE PASSWORD " & DbPassword & " NULL"

    'close database
    objAccess.CloseCurrentDatabase

    'quit Access application
    objAccess.Quit
End Sub