Доступ к файлу конфигурации из Интернета - без настроек приложения

Question

Я работаю над проектом, который требует от меня изменения файла .config для службы Windows (написанной на ASP.NET), которую я написал. Изменения необходимо внести с административного веб-сайта, который я разрабатываю. Когда пользователь выбирает кнопку «ОБНОВИТЬ» в веб-приложении, выполняется приведенный ниже код:

Protected Sub ModifyAppConfig()
        Try
            Dim configFile = "C:\App\App.exe.config"
            Dim configFileMap As New ExeConfigurationFileMap
            configFileMap.ExeConfigFilename = configFile
            Dim config As System.Configuration.Configuration
            config = ConfigurationManager.OpenMappedExeConfiguration(configFileMap, ConfigurationUserLevel.None)
            config.AppSettings.Settings("LogDirectory").Value = txtLogDirectory.Text '* EXCEPTION IS THROWN HERE *
            config.Save()
        Catch ex As Exception

        End Try
    End Sub

Когда приложение пытается получить доступ к индексу AppSettings LogDirectory, возникает исключение. Object reference not set to an instance of an object. Во время отладки AppSettings.Count = 0. Почему ни один из AppSettings не импортируется?

Я знаю, что файл открывается правильно, потому что есть данные ConnectionString. Ниже находится файл конфигурации:

<?xml version="1.0" encoding="utf-8"?>
<configuration>
    <connectionStrings>
      <add name="conn" connectionString="Data Source=DBASE;Initial Catalog=NGDevl;Integrated Security=True" providerName="System.Data.SqlClient"/>
    </connectionStrings>
    <startup> 
        <supportedRuntime version="v4.0" sku=".NETFramework,Version=v4.5"/>
    </startup>
    <appSettings>
      <add key="LogDirectory" value="C:\CTemp\"/>
    </appSettings>
</configuration>

Как я могу получить доступ и изменить значение AppSettings ("LogDirectory")?

Answer 1

Честно говоря, я не вижу ничего плохого в вашей программе.

Я создал MCVE в режиме VB.Net/Console, который может помочь при устранении неполадок

Module1.vb

Imports System.Configuration

'
' EXAMPLE OUTPUT:
'   Reading config file(test.exe.config)...
'   config.AppSettings.Settings("LogDirectory") : C : \CTemp\
'   connectionStrings: <connectionStrings>
'   <add name = "conn" connectionString="Data Source=DBASE;Initial Catalog=NGDevl;
'   Integrated Security=True" providerName="System.Data.SqlClient"/>
'     </connectionStrings>
'   appSettings: <appSettings>
'   <add key = "LogDirectory" value="C:\CTemp\"/>
'     </appSettings>
'   startup: <startup>
'   <supportedRuntime version = "v4.0" sku=".NETFramework,Version=v4.5"/>
'     </startup>
'   3 sections were found.
'
Module Module1

    Sub Main()
        ' Get filename
        Dim args() As String = System.Environment.GetCommandLineArgs()
        If args.Length <> 2 Then
            Console.WriteLine("USAGE: ReadAppConfig <\path\to\app.config>")
            Return
        End If
        Dim configFilePath As String = args(1)

        ' Open config file
        Try
            Console.WriteLine("Reading config file(" & configFilePath & ")...")
            Dim configFileMap As New ExeConfigurationFileMap
            configFileMap.ExeConfigFilename = configFilePath
            Dim config As System.Configuration.Configuration
            config = ConfigurationManager.OpenMappedExeConfiguration(configFileMap, ConfigurationUserLevel.None)

            ' Try to read AppSettings["LogDirectory"]
            Dim obj = config.AppSettings.Settings("LogDirectory")
            If IsNothing(obj) Then
                Console.WriteLine("config.AppSettings.Settings(""LogDirectory""): NULL")
            Else
                Console.WriteLine("config.AppSettings.Settings(""LogDirectory""): " & obj.Value)
            End If

            ' Dump all Sections
            Dim ct As Integer = 0
            For Each section As ConfigurationSection In config.Sections
                Dim xml = section.SectionInformation.GetRawXml
                If Not xml = Nothing Then
                    Console.WriteLine(section.SectionInformation.Name & ": " & xml)
                    ct = ct + 1
                End If
            Next
            Console.WriteLine(ct & " sections were found.")
        Catch ex As Exception
            System.Console.WriteLine("ERROR:   " & ex.Message)
        End Try

    End Sub

End Module

test.exe.config

<?xml version="1.0" encoding="utf-8"?>
<configuration>
  <connectionStrings>
    <add name="conn" connectionString="Data Source=DBASE;Initial Catalog=NGDevl;Integrated Security=True" providerName="System.Data.SqlClient"/>
  </connectionStrings>
  <startup>
    <supportedRuntime version="v4.0" sku=".NETFramework,Version=v4.5"/>
  </startup>
  <appSettings>
    <add key="LogDirectory" value="C:\CTemp\"/>
  </appSettings>
</configuration>

• Проект> test.exe.config: Я установил для свойства «Копировать в вывод» значение «Копировать, если новее»

• Проект> Свойства> Отладка: Я установил «Аргументы командной строки» в «test.exe.config»

Надеюсь, это поможет ...