Как найти значение E1 в cloumn2, а затем заменить на значение column1 с помощью макроса?

Question

Я хочу найти значение, доступное в ячейке E1, в строки column2, а затем заменить его значением column1.Например, значение

B2 следует заменить с ABC-1 на A-1.Значение B3 следует заменить с ABC-1 на B-1

и т. Д.

Я новичок в макросах.

Я пытался поместить код из Интернета

Sub FindReplaceAll()

Dim fnd As Variant
Dim rplc As Variant  

fnd = "ABC"
rplc = Cells(i, 8).Value

Dim lastRow As Long
lastRow = Cells(Rows.Count, 4).End(xlUp).row

Dim i As Long

For i = 2 To lastRow
    If Not IsEmpty(Cells(i, 4)) Then
          Cells.Replace what:=fnd, Replacement:=rplc
    End If
Next

End Sub

Answer 1

Немного отредактировал ваш код в соответствии с описанными вами потребностями (если он правильно понят)

• Вы всегда ищете значение в абсолютной ячейке E1
• Вы заменяетезначение поиска в столбце B с полным значением из столбца A

Мои примеры данных на основе ваших комментариев:

Sub FindReplaceAll()

Dim fnd As String, rplc As String, i As Long

With ActiveWorkbook.Sheets("Sheet1") 'Your sheetname goes here
    fnd = .Range("E1").Value
    For i = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
        .Cells(i, 2).Replace what:=fnd, Replacement:=.Cells(i, 1).Value
    Next i
End With

End Sub

После запуска макроса:

И в случае, если вы можете просто сделать это с помощью формулы и избежать VBA (особенно, если вы новичок в этом),например в C2 положить:

=IF(LEFT(B2,(SEARCH("-",B2)-1))=$E$1,A2&RIGHT(B2,LEN(B2)-SEARCH("-",B2)+1),B2)

и перетащить вниз ...

Answer 2

Попробуйте:

Option Explicit

Sub FindReplaceAll()

    Dim SearchString As String
    Dim LastRow As Long, i As Long

    With ThisWorkbook.Worksheets("Sheet1")
        'Find the last row of column A
        LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        'Set the SearchString equal to the value of cell E1
        SearchString = .Range("E1").Value

        'Loop from second row to lastrow
        For i = 2 To LastRow
            'If the value of cell B & i equal to SearchString
            If (.Range("B" & i).Value <> "") And (.Range("B" & i).Value = SearchString) Then
                'Cell B & i equal to A & i
                .Range("B" & i).Value = .Range("A" & i).Value
            End If

        Next i

    End With

End Sub

Answer 3

См. Комментарии в коде для более подробной информации, но дайте мне знать, если это делает то, что вы просите:

Sub FindReplaceAll()

Dim ws As Worksheet: Set ws = ActiveWorkbook.Sheets("sheet name") '<-- set your sheet name
Dim lRow As Long: lRow = ws.Cells(Rows.Count, "A").End(xlUp).Row 'get last row in column A
Dim arrData As Variant: arrData = ws.Range("A1:E" & lRow) 'declare and allocate data to an array

Dim R As Long, C As Long

For R = LBound(arrData) To UBound(arrData)
    If arrData(R, 5) = arrData(R, 2) Then 'if E matches the value in B
    'If arrData(1, 5) = arrData(R, 2) Then 'Alternative if E1 is a fixed value, and not for every row
        ws.Cells(R, 2) = arrData(R, 1) 'allocate the A value to B
    End If
Next R

End Sub