Формула для подсчета повторяющихся "пар"

Question

В следующем примере каков наилучший способ оценки ' лучшей команды ', то есть пары , которая постоянно повторяется ?

| Winner In Event A     | Winner In Event B     |
|-------------------    |-------------------    |
| Bob                   | Alfred                |
| Bob                   | Dave                  |
| Bob                   | Alfred                |
| Jason                 | Alfred                |
| John                  | Fred                  |
| Fred                  | John                  |
| John                  | Fred                  |
| Richard               | Jason                 |
| Richard               | Bob                   |

В этом случае я бы ожидал, что он выберет Фред и Джон , так как они соединены 3 раза и не связаны с Бобом и Альфредом, которые соединены только 2 раза.

В приведенном выше примере я включаю стандартный VLookup, который, я уверен, содержит ключ к решению, но я не уверен, как выглядит парная версия

Answer 1

без 3-го столбца:

=INDEX(ARRAYFORMULA(QUERY(IF(LEN(A1:A&B1:B), 
 IF(A1:A>B1:B, A1:A&" & "&B1:B, B1:B&" & "&A1:A), ), 
 "select Col1,count(Col1) group by Col1 order by count(Col1) desc", 0)), 2, 1)

---

полная таблица:

=ARRAYFORMULA(QUERY(IF(LEN(A1:A&B1:B), 
 IF(A1:A>B1:B, A1:A&" & "&B1:B, B1:B&" & "&A1:A), ), 
 "select Col1,count(Col1) 
  where Col1 is not null
  group by Col1 
  order by count(Col1) desc
  label count(Col1)''", 0))

Answer 2

Я понял это и поместил в приведенный выше пример, по сути, создайте третий столбец, подобный этому, который имеет значение этого типа

=IF(A14>B14, A14&" & "&B14, B14&" & "&A14)

Что даст вам что-то вроде

| Winner In Event A     | Winner In Event B     | Ordered Team      |
|-------------------    |-------------------    |-----------------  |
| Bob                   | Alfred                | Bob & Alfred      |
| Bob                   | Dave                  | Dave & Bob        |
| Bob                   | Alfred                | Bob & Alfred      |
| Jason                 | Alfred                | Jason & Alfred    |
| John                  | Fred                  | John & Fred       |
| Fred                  | John                  | John & Fred       |
| John                  | Fred                  | John & Fred       |
| Richard               | Jason                 | Richard & Jason   |
| Richard               | Bob                   | Richard & Bob     |

Тогда вы можете просто посчитать наиболее распространенное значение из 3-го столбца, который, когда я гуглил , выглядел следующим образом

=ARRAYFORMULA(INDEX(C14:C29,MATCH(MAX(COUNTIF(C14:C29,C14:C29)),COUNTIF(C14:C29,C14:C29),0)))